#include "..\script_component.hpp"

/*
 * Author: IDSolutions
 * Opens the bank dialog.
 *
 * Arguments:
 * None
 *
 * Return Value:
 * None
 *
 * Example:
 * [] call forge_client_bank_fnc_openBank;
 *
 * Public: Yes
 */

private _productVersion = productVersion;
private _steamBranchName = _productVersion select 8;
private _payMultiplier = "MULTIPLYR" call BFUNC(getParamValue);

if (_steamBranchName == "profiling") then {
    private _display = (findDisplay 46) createDisplay "RscWebBank";
    private _ctrl = _display displayCtrl 2025;

    _ctrl ctrlAddEventHandler ["JSDialog", {
        params ["_control", "_isConfirmDialog", "_message"];
        [QGVAR(handleEvents), [_control, _isConfirmDialog, _message]] call CFUNC(localEvent);
    }];

    _ctrl ctrlWebBrowserAction ["LoadFile", QUOTE(PATHTOF(ui\_site\index.html))];
    // _ctrl ctrlWebBrowserAction ["OpenDevConsole"];
} else {
    disableSerialization;
    createDialog "RscBankDialog";

    private _uid = getPlayerUID player;
    private _bank = GETVAR(player,FORGE_Bank,0); //TODO: Implement balance from server
    private _cash = GETVAR(player,FORGE_Cash,0); //TODO: Implement cash from server
    private _plyscore = rating player;
    private _pending = _plyscore * _payMultiplier;

    private _formattedBank = _bank call EFUNC(misc,formatNumber);
    private _formattedCash = _cash call EFUNC(misc,formatNumber);
    private _formattedPending = _pending call EFUNC(misc,formatNumber);

    ctrlSetText [IDC_CASHTEXT, format ["Cash: $%1", _formattedCash]];
    ctrlSetText [IDC_BANKTEXT, format ["Bank: $%1", _formattedBank]];
    ctrlSetText [IDC_RATINGTEXT, format ["Pending: %1", _formattedPending]];
    ctrlSetText [IDC_TIMESHEETTEXT, "Ready for Timesheet"];

    {
        lbAdd [IDC_PLAYERINPUT, name _x];
        lbSetData [IDC_PLAYERINPUT, _forEachIndex, netId _x];
    } forEach allPlayers;

    lbSetCurSel [IDC_PLAYERINPUT, 0];
    ctrlSetText [IDC_AMOUNTINPUT, ""];
};