#include "..\script_component.hpp"

/*
 * Author: IDSolutions
 * Selects a product from the store
 *
 * Arguments:
 * None
 *
 * Return Value:
 * None
 *
 * Example:
 * _this call forge_store_fnc_selectProduct
 *
 * Public: No
 */

private _display = findDisplay IDD_STOREDIALOG;
private _productList = _display displayCtrl IDC_PRODUCTLIST;
private _productIndex = lbCurSel _productList;
private _productData = lbData [IDC_PRODUCTLIST, _productIndex];
private _product = call compile _productData;

_product params [["_item", "", [""]], ["_price", 0, [0]], ["_category", "", [""]], ["_configType", "", [""]], ["_itemType", "", [""]]];

switch (_configType) do {
    case "item";
    case "weapon";
    case "magazine";
    case "backpack": {
        [_item, _price, _configType, _itemType] call FUNC(buyItem);
    };
    case "vehicle": {
        [_item, _price, _itemType] call FUNC(buyVehicle);
    };
};