#include "..\script_component.hpp"

/*
 * Author: IDSolutions
 * Registers an hostage task
 *
 * Arguments:
 * 0: ID of the task <STRING>
 * 1: Amount of hostages KIA to fail the task <NUMBER>
 * 2: Amount of hostages rescued to complete the task <NUMBER>
 * 3: Marker name for the extraction zone <STRING>
 * 4: Amount of funds the company recieves if the task is successful <NUMBER> (default: 0)
 * 5: Amount of rating the company and player lose if the task is failed <NUMBER> (default: 0)
 * 6: Amount of rating the company and player recieve if the task is successful <NUMBER> (default: 0)
 * 7: Subcategory of task <ARRAY> (default: [false, true])
 * 8: Should the mission end (MissionSuccess) if the task is successful <BOOL> (default: false)
 * 9: Should the mission end (MissionFailed) if the task is failed <BOOL> (default: false)
 * 10: Amount of time before hostage(s) die <NUMBER> (default: nil)
 * 11: Marker name for the cbrn zone <STRING> (default: nil)
 *
 * Return Value:
 * None
 *
 * Example:
 * ["task_name", 1, 2, "marker_name", 1500000, -75, 500, [false, true], false, false] spawn forge_client_task_fnc_hostage;
 * ["task_name", 1, 2, "marker_name", 1500000, -75, 500, [false, true], false, false, 45] spawn forge_client_task_fnc_hostage;
 * ["task_name", 1, 2, "marker_name", 1500000, -75, 500, [true, false], false, false, 45, "marker_name"] spawn forge_client_task_fnc_hostage;
 *
 * Public: Yes
 */

params [["_taskID", ""], ["_limitFail", -1], ["_limitSuccess", -1], ["_extZone", ""], ["_companyFunds", 0], ["_ratingFail", 0], ["_ratingSuccess", 0], ["_type", [["_cbrn", false], ["_hostage", true]]], ["_endSuccess", false], ["_endFail", false], "_time", ["_cbrnZone", ""]];

private _cbrn = (_this select 7) select 0;
private _hostage = (_this select 7) select 1;
private _result = 0;

waitUntil {
	sleep 1;
	_hostages = GVAR(allHostages) select { (_x getVariable ["assignedTask", ""]) == _taskID };
	count  _hostages > 0
};

waitUntil {
	sleep 1;
	_shooters = GVAR(allShooters) select { (_x getVariable ["assignedTask", ""]) == _taskID };
	count  _shooters > 0
};

private _hostages = GVAR(allHostages) select { (_x getVariable ["assignedTask", ""]) == _taskID };
private _shooters = GVAR(allShooters) select { (_x getVariable ["assignedTask", ""]) == _taskID };
private _startTime = if (!isNil "_time") then { floor(time) } else { nil };

waitUntil {
	sleep 1;

	private _hostagesFreed = ({ !captive _x } count _hostages);
	private _hostagesInZone = ({ _x inArea _extZone } count _hostages);
	private _hostagesKilled = ({ !alive _x } count _hostages);
	private _shootersAlive = ({ alive _x } count _shooters);

	if (!isNil "_time") then {
		private _timeExpired = (floor time - _startTime >= _time);
		
		if (_hostagesFreed < _limitSuccess && _timeExpired) then { _result = 1; };        
		if (_hostagesKilled >= _limitFail) then { _result = 1; };
		
		(_result == 1) or
		((_hostagesInZone >= _limitSuccess) && (_hostagesKilled < _limitFail)) or
		((!isNil "_shooters") && (_shootersAlive <= 0) && (_hostagesInZone >= _limitSuccess) && (_hostagesKilled < _limitFail))
	} else {
		if (_hostagesKilled >= _limitFail) then { _result = 1; };
		
		(_result == 1) or
		((_hostagesInZone >= _limitSuccess) && (_hostagesKilled < _limitFail)) or
		((!isNil "_shooters") && (_shootersAlive <= 0) && (_hostagesInZone >= _limitSuccess) && (_hostagesKilled < _limitFail))
	};
};

if (_result == 1) then {
	if (_cbrn) then {
		"SmokeShellYellow" createVehicle getMarkerPos _cbrnZone;

		sleep 5;

		{
			if (captive _x) then {
				_x setDamage 0.9;
				_x playMove "acts_executionvictim_kill_end";

				sleep 2.75;

				_x setDamage 1;
			}
		} forEach _hostages;
	};

	if (_hostage) then {
		{
			_x enableAIFeature ["MOVE", true];
			_x playMove "";
		} forEach _shooters;

		sleep 1;

		{ _x setCaptive false; } forEach _hostages;

		sleep 5;
	};

	{ deleteVehicle _x } forEach _hostages;
	{ deleteVehicle _x } forEach _shooters;

	[_taskID, "FAILED"] call BFUNC(taskSetState);

	if (_endFail) then {
		["MissionFail", false] remoteExecCall ["BIS_fnc_endMission", playerSide];
	};

	// ["deduct", _ratingFail] remoteExecCall ["forge_server_rating_fnc_handleRating", 2];
	[_ratingFail] call EFUNC(org,addReputation);
	[format ["Task failed: %1 reputation", _ratingFail], "warning", 5, "right"] call EFUNC(misc,notify);

	sleep 1;

	{ [_x, _ratingFail] remoteExec ["addRating", -2] } forEach allPlayers;
} else {
	{ deleteVehicle _x } forEach _hostages;
	{ deleteVehicle _x } forEach _shooters;

	[_taskID, "SUCCEEDED"] call BFUNC(taskSetState);

	if (_endSuccess) then {
		["MissionSuccess", true] remoteExecCall ["BIS_fnc_endMission", playerSide];
	};

	// ["advance", _ratingSuccess] remoteExecCall ["forge_server_rating_fnc_handleRating", 2];
	[_ratingSuccess] call EFUNC(org,addReputation);
	[format ["Task completed: %1 reputation", _ratingSuccess], "success", 5, "right"] call EFUNC(misc,notify);

	sleep 1;

	{ [_x, _ratingSuccess] remoteExec ["addRating", -2] } forEach allPlayers;

	// ["advance", _companyFunds] remoteExecCall ["forge_server_money_fnc_handleFunds", 2];
	[_companyFunds] call EFUNC(org,addFunds);
	[format ["Task completed: %1 funds", _companyFunds], "success", 5, "right"] call EFUNC(misc,notify);
};