#include "..\script_component.hpp"

/*
 * Author: IDSolutions
 * Registers an attack task
 *
 * Arguments:
 * 0: ID of the task <STRING>
 * 1: Amount of targets escaped to fail the task <NUMBER>
 * 2: Amount of targets eliminated to complete the task <NUMBER>
 * 3: Amount of funds the company recieves if the task is successful <NUMBER> (default: 0)
 * 4: Amount of rating the company and player lose if the task is failed <NUMBER> (default: 0)
 * 5: Amount of rating the company and player recieve if the task is successful <NUMBER> (default: 0)
 * 6: Should the mission end (MissionSuccess) if the task is successful <BOOL> (default: false)
 * 7: Should the mission end (MissionFailed) if the task is failed <BOOL> (default: false)
 * 8: Amount of time before target(s) escape <NUMBER> (default: -1)
 * 9: Equipment rewards <ARRAY> (default: [])
 * 10: Supply rewards <ARRAY> (default: [])
 * 11: Weapon rewards <ARRAY> (default: [])
 * 12: Vehicle rewards <ARRAY> (default: [])
 * 13: Special rewards <ARRAY> (default: [])
 *
 * Return Value:
 * None
 *
 * Example:
 * ["task_name", 1, 2, 1500000, -75, 375, false, false] spawn forge_client_task_fnc_attack;
 * ["task_name", 1, 2, 1500000, -75, 375, false, false, 45] spawn forge_client_task_fnc_attack;
 *
 * Public: Yes
 */

params [
	["_taskID", "", [""]], 
	["_limitFail", -1, [0]], 
	["_limitSuccess", -1, [0]], 
	["_companyFunds", 0, [0]], 
	["_ratingFail", 0, [0]], 
	["_ratingSuccess", 0, [0]], 
	["_endSuccess", false, [false]], 
	["_endFail", false, [false]], 
	["_time", -1, [0]], 
	["_equipmentRewards", [], [[]]], 
	["_supplyRewards", [], [[]]], 
	["_weaponRewards", [], [[]]], 
	["_vehicleRewards", [], [[]]], 
	["_specialRewards", [], [[]]]
];

private _result = 0;

waitUntil {
	sleep 1;
	_targets = GVAR(allTargets) select { (_x getVariable ["assignedTask", ""]) == _taskID };
	count _targets > 0
};

private _targets = GVAR(allTargets) select { (_x getVariable ["assignedTask", ""]) == _taskID };
private _startTime = if (!isNil "_time") then { floor(time) } else { nil };

waitUntil {
	sleep 1;

	private _targetsKilled = ({ !alive _x } count _targets);

	if (_time isNotEqualTo -1) then {
		private _timeExpired = (floor time - _startTime >= _time);

		if (_targetsKilled < _limitSuccess && _timeExpired) then { _result = 1; };

		(_result == 1) or (_targetsKilled >= _limitSuccess)
	} else {
		(_targetsKilled >= _limitSuccess)
	};
};

if (_result == 1) then {
	{ deleteVehicle _x } forEach _targets;

	[_taskID, "FAILED"] call BFUNC(taskSetState);

    private _penalties = createHashMap;
    _penalties set ["reputation", _ratingFail];

    [_taskID, _penalties] call FUNC(handleTaskRewards);

    sleep 1;
    
    { [_x, _ratingFail] remoteExec ["addRating", -2] } forEach allPlayers;
    [format ["Task failed: %1 reputation", _ratingFail], "warning", 5, "right"] call EFUNC(misc,notify);

    if (_endFail) then { ["MissionFail", false] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
} else {
	{ deleteVehicle _x } forEach _targets;

	private _rewards = createHashMap;
    _rewards set ["funds", _companyFunds];
    _rewards set ["reputation", _ratingSuccess];

    if (count _equipmentRewards > 0) then { _rewards set ["equipment", _equipmentRewards]; };
    if (count _supplyRewards > 0) then { _rewards set ["supplies", _supplyRewards]; };
    if (count _weaponRewards > 0) then { _rewards set ["weapons", _weaponRewards]; };
    if (count _vehicleRewards > 0) then { _rewards set ["vehicles", _vehicleRewards]; };
    if (count _specialRewards > 0) then { _rewards set ["special", _specialRewards]; };
    
    [_taskID, _rewards] call FUNC(handleTaskRewards);
    [_taskID, "SUCCEEDED"] call BIS_fnc_taskSetState;

    sleep 1;

    { [_x, _ratingSuccess] remoteExec ["addRating", -2] } forEach allPlayers;

    [format ["Task completed: %1 reputation", _ratingSuccess], "success", 5, "right"] call EFUNC(misc,notify);
	[format ["Task completed: %1 funds", _companyFunds], "success", 5, "right"] call EFUNC(misc,notify);
    
    if (_endSuccess) then { ["MissionSuccess", true] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
};