#include "..\script_component.hpp"

params ["_item", "_price", "_configType", "_itemType"];

private _displayName = "";
// private _locker = player getVariable ["FORGE_Locker", []];
private _locker = GETVAR(player,FORGE_Locker,[]);

if !([_price] call FUNC(handlePurchase)) exitWith {};

switch (_configType) do {
    case "item": {
        _displayName = getText (configFile >> "CfgWeapons" >> _item >> "displayName");
        _locker pushBack [_itemType, _item];
    };
    case "weapon": {
        _displayName = getText (configFile >> "CfgWeapons" >> _item >> "displayName");
        _locker pushBack [_itemType, _item];
    };
    case "magazine": {
        _displayName = getText (configFile >> "CfgMagazines" >> _item >> "displayName");
        _locker pushBack [_itemType, [_item, getNumber (configFile >> "CfgMagazines" >> _item >> "count"), getNumber (configFile >> "CfgMagazines" >> _item >> "count")]];
    };
    case "backpack": {
        _displayName = getText (configFile >> "CfgVehicles" >> _item >> "displayName");
        _locker pushBack [_itemType, _item];
    };
};

// player setVariable ["FORGE_Locker", _locker, true];
SETPVAR(player,FORGE_Locker,_locker);

[_item, _itemType] call EFUNC(armory,addItemArmory);

[format ["You have purchased %1 for $%2.", _displayName, _price], "info", 3, "right"] call EFUNC(misc,notify);