44625a8677
All checks were successful
Build / Build (push) Successful in 27s
This commit refactors and adds documentation to several client-side functions across various addons, including: - **Task Addon:** Added function headers and descriptions to task-related functions (fnc_destroy, fnc_attack, fnc_defuse, fnc_hostage, fnc_makeIED, fnc_hvt, fnc_heartBeat, fnc_makeTarget, fnc_makeHVT, fnc_makeHostage, fnc_makeObject, fnc_makeShooter, fnc_attackModule, fnc_destroyModule, fnc_hvtModule, fnc_hostageModule, fnc_defuseModule, fnc_protectedModule, fnc_hostagesModule, fnc_explosivesModule, fnc_shootersModule). - **Org Addon:** Updated author and added function headers/descriptions to organization-related functions (fnc_initOrgStore, fnc_requestServerDB, fnc_addAsset, fnc_addReputation, fnc_create, fnc_removeAsset, fnc_addFunds, fnc_leave, fnc_addMember, fnc_disband, fnc_verifyOrgStore, fnc_handleOrgLoad). - **Garage Addon:** Added function headers and descriptions to garage-related functions (fnc_openGarage, fnc_fetchNearby, fnc_initGarage, fnc_fetchGarage, fnc_storeVehicle). - **Locker Addon:** Added function headers and descriptions to locker-related functions (fnc_openLocker, fnc_fetchPlayer, fnc_initLocker, fnc_fetchLocker). - **Phone Addon:** Added function headers, descriptions, and examples to phone-related functions (fnc_initAction, fnc_showEmail, fnc_showMessage, fnc_delEmail, fnc_delMsg, fnc_showMessageInput, fnc_addContact, fnc_initPhone, fnc_addMsg, fnc_addEmail, fnc_newEmail, fnc_initVar, fnc_addOfflineEmail, fnc_addOfflineMsg, fnc_sendMsg, fnc_sendEmail, fnc_showContact, fnc_newMsg, fnc_dateToHhMm, fnc_initAddAction, fnc_openPhone, fnc_viewSettings, fnc_viewMessages, fnc_viewContacts, fnc_viewEmail, fnc_showDialpad, fnc_showSafari). - **Admin Addon:** Added function headers and descriptions to admin-related functions (fnc_adminMessage, fnc_printAddonName, fnc_initAdmin, fnc_openAdmin, fnc_adminPromote). - **Store Addon:** Added function headers and descriptions to store-related functions (fnc_openStore, fnc_initStore, fnc_selectProduct, fnc_changeFilter, fnc_changePayment, fnc_handlePurchase). - **Medical Addon:** Added function headers, descriptions, and examples to medical-related functions (fnc_saveDroppedWeapons, fnc_moveInventory, fnc_onRespawn, fnc_onKilled, fnc_initMedical, fnc_deductMedicalCost, fnc_heartBeat). - **Misc Addon:** Added function headers, descriptions, and examples to misc-related functions (fnc_formatNumber, fnc_isAssignableBinocular, fnc_isWeaponType, fnc_cargoToPairs, fnc_serializeString, fnc_deserializeString, fnc_getSystemTime). - **Init Addon:** Updated author and removed unnecessary copyright information from init-related functions (fnc_initPlayer, fnc_playerDBSave, fnc_playerSaveLoop, fnc_playerDBLoad, fnc_handlePlayerLoad). - **Money Addon:** Removed unnecessary copyright information from money-related functions (fnc_takeCash, fnc_giveCash, fnc_giveCashSubmit). - **Interaction Addon:** Removed unnecessary copyright information from interaction-related functions (fnc_initInteraction, fnc_openInteraction, fnc_interactionAction). - **Ambient Addon:** Removed unnecessary copyright information from ambient-related functions (fnc_ambientSound). - **Arsenal Addon:** Added function headers, descriptions, and examples to arsenal-related functions (fnc_openArmory, fnc_saveUnlocks, fnc_updateUnlocks, fnc_openGarage, fnc_addGarageVehicle, fnc_addVirtualVehicles, fnc_addVirtualVehicles). - **Dialogue Addon:** Added function headers and descriptions to dialogue-related functions (fnc_selectAI, fnc_selectDialogue). - **Service Addon:** Added function headers and descriptions to service-related functions (fnc_initService). - **Bank Addon:** Added function headers and descriptions to bank-related functions (fnc_initBank, fnc_refresh, fnc_openBank). These changes improve code readability, maintainability, and provide better context for developers working with these functions. The author field was updated to `IDSolutions` where appropriate.
81 lines
2.4 KiB
Plaintext
81 lines
2.4 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* Function: forge_client_init_fnc_initPlayer
|
|
* Author: IDSolutions
|
|
*
|
|
* [Description]
|
|
* Initialize player.
|
|
*
|
|
* Arguments:
|
|
* N/A
|
|
*
|
|
* Return Value:
|
|
* N/A
|
|
*
|
|
* Examples:
|
|
* [] call forge_client_init_fnc_initPlayer (Server or Singleplayer Only)
|
|
* [] remoteExecCall ["forge_client_init_fnc_initPlayer", 2, false] (Multiplayer Only)
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
waitUntil { !isNull player };
|
|
waitUntil { player == player };
|
|
waitUntil { alive player };
|
|
|
|
removeAllWeapons player;
|
|
removeAllAssignedItems player;
|
|
removeUniform player;
|
|
removeVest player;
|
|
removeBackpack player;
|
|
removeGoggles player;
|
|
removeHeadgear player;
|
|
|
|
SETPVAR(player,value_loadDone,false);
|
|
cutText ["Loading In...", "BLACK", 1];
|
|
|
|
// ["hgetall", "", "", -1, [], "forge_client_init_fnc_handlePlayerLoad", true] spawn dragonfly_db_fnc_addTask;
|
|
["hgetallid", getPlayerUID player, "", -1, [], "forge_client_init_fnc_handlePlayerLoad", true, netId player] remoteExec ["dragonfly_db_fnc_addTask", 2, false];
|
|
|
|
[] spawn FUNC(playerSaveLoop);
|
|
[] spawn EFUNC(interaction,initInteraction);
|
|
|
|
waitUntil { GETVAR(player,value_loadDone,false) };
|
|
cutText ["", "PLAIN", 1];
|
|
|
|
waitUntil { !(isNull (findDisplay 46)) };
|
|
(findDisplay 46) displayAddEventHandler ["KeyDown", {
|
|
switch (_this select 1) do {
|
|
// Interaction Interface (default key TAB)
|
|
case ((configFile >> "CfgPatches" >> "forge_client_main" >> "interactionKey") call BFUNC(getCfgData)): {
|
|
[] call EFUNC(interaction,openInteraction);
|
|
false;
|
|
};
|
|
// Holster/Unholster (default key H)
|
|
case ((configFile >> "CfgPatches" >> "forge_client_main" >> "holsterKey") call BFUNC(getCfgData)): {
|
|
if ((currentWeapon player) != "" && !(GETVAR(player,FORGE_Holster_Weapon,true))) then {
|
|
player action ["SwitchWeapon", player, player, 299];
|
|
SETPVAR(player,FORGE_Holster_Weapon,true);
|
|
} else {
|
|
private _weapon = switch (true) do {
|
|
case ((primaryWeapon player) != ""): { primaryWeapon player };
|
|
case ((handgunWeapon player) != ""): { handgunWeapon player };
|
|
case ((secondaryWeapon player) != ""): { secondaryWeapon player };
|
|
default {""};
|
|
};
|
|
if (_weapon != "") then { player selectWeapon _weapon };
|
|
SETPVAR(player,FORGE_Holster_Weapon,false);
|
|
};
|
|
false;
|
|
};
|
|
// Open Phone (default key P)
|
|
case ((configFile >> "CfgPatches" >> "forge_client_main" >> "phoneKey") call BFUNC(getCfgData)): {
|
|
[] spawn EFUNC(phone,openPhone);
|
|
false;
|
|
};
|
|
default {
|
|
false;
|
|
};
|
|
};
|
|
}]; |