c87deec60b
All checks were successful
Build / Build (push) Successful in 26s
This commit refactors how organization funds and reputation are handled, updates task completion logic to use the new organization functions, and modifies player saving to include organization data. Additionally, it introduces string serialization/deserialization and fixes a player save loop. * **Organization Funds and Reputation:** Replaces direct server calls for handling funds and reputation with calls to the new organization functions (`EFUNC(org,addFunds)` and `EFUNC(org,addReputation)`). This centralizes fund and reputation management within the organization store. * **Task Completion Logic:** Updates task completion functions (`fnc_destroy.sqf`, `fnc_attack.sqf`, `fnc_hostage.sqf`, `fnc_hvt.sqf`, `fnc_defuse.sqf`) to use the new organization functions for adding funds and reputation upon task success or failure. Also adds notifications to inform the player of reputation and fund changes. * **Player Saving:** Modifies the player saving function (`fnc_playerDBSave.sqf`) to include the player's organization ID in the saved data. * **String Serialization/Deserialization:** Adds `serializeString` and `deserializeString` PREP macros to `XEH_PREP.hpp` and uses them in `fnc_handleOrgLoad.sqf` and `fnc_create.sqf` to handle special characters in organization and member names. * **Player Save Loop Fix:** Removes unnecessary brackets from the `call FUNC(playerDBSave)` in `fnc_playerSaveLoop.sqf`. * **Organization Purchase Verification:** Adds organization ownership verification to `fnc_handlePurchase.sqf` to ensure only the owner can make purchases using organization funds. * **Player Initialization:** Updates `fnc_initPlayer.sqf` to retrieve and set the player's organization upon initialization.
95 lines
3.2 KiB
Plaintext
95 lines
3.2 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* Author: Creedcoder, J. Schmidt
|
|
* Registers a defuse task.
|
|
*
|
|
* Arguments:
|
|
* 0: ID of the task <STRING>
|
|
* 1: Amount of entities destroyed to fail the task <NUMBER>
|
|
* 2: Amount of ieds defused to complete the task <NUMBER>
|
|
* 3: Amount of funds the company recieves if the task is successful <NUMBER> (default: 0)
|
|
* 4: Amount of rating the company and player lose if the task is failed <NUMBER> (default: 0)
|
|
* 5: Amount of rating the company and player recieve if the task is successful <NUMBER> (default: 0)
|
|
* 6: Should the mission end (MissionSuccess) if the task is successful <BOOL> (default: false)
|
|
* 7: Should the mission end (MissionFailed) if the task is failed <BOOL> (default: false)
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* ["task_name", 2, 3, 375000, -75, 300, false, false] spawn forge_client_task_fnc_defuse;
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
params [["_taskID", ""], ["_limitFail", -1], ["_limitSuccess", -1], ["_companyFunds", 0], ["_ratingFail", 0], ["_ratingSuccess", 0], ["_endSuccess", false], ["_endFail", false]];
|
|
|
|
private _result = 0;
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
_ieds = GVAR(allIEDs) select { (_x getVariable ["assignedTask", ""]) == _taskID };
|
|
count _ieds > 0
|
|
};
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
_entities = GVAR(allEntities) select { (_x getVariable ["assignedTask", ""]) == _taskID };
|
|
count _entities > 0
|
|
};
|
|
|
|
private _ieds = GVAR(allIEDs) select { (_x getVariable ["assignedTask", ""]) == _taskID };
|
|
private _entities = GVAR(allEntities) select { (_x getVariable ["assignedTask", ""]) == _taskID };
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
|
|
private _entitiesDestroyed = ({ !alive _x } count _entities);
|
|
|
|
if (_entitiesDestroyed >= _limitFail) then { _result = 1; };
|
|
|
|
(_result == 1) or ((GVAR(defusedCount) >= _limitSuccess) && (_entitiesDestroyed < _limitFail))
|
|
};
|
|
|
|
if (_result == 1) then {
|
|
{ deleteVehicle _x } forEach _ieds;
|
|
{ deleteVehicle _x } forEach _entities;
|
|
|
|
[_taskID, "FAILED"] call BFUNC(taskSetState);
|
|
|
|
if (_endFail) then {
|
|
["MissionFail", false] remoteExecCall ["BIS_fnc_endMission", playerSide];
|
|
};
|
|
|
|
// ["deduct", _ratingFail] remoteExecCall ["forge_server_rating_fnc_handleRating", 2];
|
|
[_ratingFail] call EFUNC(org,addReputation);
|
|
[format ["Task failed: %1 reputation", _ratingFail], "warning", 5, "right"] call EFUNC(misc,notify);
|
|
|
|
sleep 1;
|
|
|
|
{ [_x, _ratingFail] remoteExec ["addRating", -2] } forEach allPlayers;
|
|
} else {
|
|
{ deleteVehicle _x } forEach _ieds;
|
|
{ deleteVehicle _x } forEach _entities;
|
|
|
|
[_taskID, "SUCCEEDED"] call BFUNC(taskSetState);
|
|
|
|
if (_endSuccess) then {
|
|
["MissionSuccess", true] remoteExecCall ["BIS_fnc_endMission", playerSide];
|
|
};
|
|
|
|
// ["advance", _ratingSuccess] remoteExecCall ["forge_server_rating_fnc_handleRating", 2];
|
|
[_ratingSuccess] call EFUNC(org,addReputation);
|
|
[format ["Task completed: %1 reputation", _ratingSuccess], "success", 5, "right"] call EFUNC(misc,notify);
|
|
|
|
sleep 1;
|
|
|
|
{ [_x, _ratingSuccess] remoteExec ["addRating", -2] } forEach allPlayers;
|
|
|
|
// ["advance", _companyFunds] remoteExecCall ["forge_server_money_fnc_handleFunds", 2];
|
|
[_companyFunds] call EFUNC(org,addFunds);
|
|
[format ["Task completed: %1 funds", _companyFunds], "success", 5, "right"] call EFUNC(misc,notify);
|
|
};
|
|
|
|
GVAR(defusedCount) = 0; |