613f05d52a
This commit introduces several changes related to database interactions and client-side functionality: * **Database Response Handling:** Implements a mechanism to handle responses from server requests, specifically for database operations. This includes setting up a callback system to process results based on request IDs. * **Store Functionality:** Corrects a typo in the `fnc_buyItem.sqf` script, changing `EFUNC(armory,addArmoryItem)` to `EFUNC(arsenal,addArmoryItem)`. * **Inventory Management:** Improves the `fnc_moveInventory.sqf` script by correcting a conditional statement to ensure proper handling of inventory items. * **Configuration Updates:** Updates the mod configuration (`CfgMods.hpp`) to use the correct path for the mod picture. * **Client Initialization:** Adds a client registration call to the server during client post-initialization (`XEH_postInit_client.sqf`). * **Workflow Update:** Updates the build workflow to use the latest Ubuntu runner. * **Database Preparation:** Removes unnecessary preparations from `XEH_postInit.sqf` and `XEH_PREP.hpp`.
44 lines
1.4 KiB
Plaintext
44 lines
1.4 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* Function: forge_client_org_fnc_addReputation
|
|
* Author: J. Schmidt
|
|
*
|
|
* Description:
|
|
* Adds reputation to an organization
|
|
*
|
|
* Arguments:
|
|
* 0: _uid - Player UID <STRING>
|
|
* 1: _name - Organization name <STRING>
|
|
* 2: _amount - Amount of reputation to add (can be negative) <NUMBER>
|
|
*
|
|
* Return Value:
|
|
* New reputation amount <NUMBER>
|
|
*/
|
|
|
|
params [["_uid", "", [""]], ["_name", "", [""]], ["_amount", 0, [0]]];
|
|
|
|
if (_uid == "" || _name == "") exitWith { TRACE_2("Invalid parameters for adding reputation",_uid,_name); nil };
|
|
|
|
private _store = call FUNC(verifyOrgStore);
|
|
private _key = format ["%1_%2", _uid, _name];
|
|
private _org = _store call ["getByKey", [_key]];
|
|
|
|
private _timestamp = systemTimeUTC apply { if (_x < 10) then { "0" + str _x } else { str _x }};
|
|
private _dateTime = format ["%1-%2-%3_%4:%5:%6.%7", _timestamp#0, _timestamp#1, _timestamp#2, _timestamp#3, _timestamp#4, _timestamp#5, _timestamp#6];
|
|
|
|
if (isNil "_org") exitWith { TRACE_1("Organization not found",_key); nil };
|
|
|
|
private _reputation = _org get "reputation";
|
|
private _logs = _org get "logs";
|
|
private _owner = _org get "owner";
|
|
private _newReputation = _reputation + _amount;
|
|
|
|
_org set ["reputation", _newReputation];
|
|
|
|
_logs pushBack [_dateTime, "REPUTATION", _amount, _newReputation];
|
|
_org set ["logs", _logs];
|
|
|
|
_store call ["post", [_owner, _name]];
|
|
|
|
_newReputation |