#include "..\script_component.hpp"

/*
 * Function: dragonfly_db_fnc_hashGetAll
 * Author: Creedcoder, J.Schmidt
 * Edit: 07.15.2024
 *
 * [Description]
 * Get all fields and values from the default hash and return them via callback.
 *
 * Arguments:
 * 0: Name of function to return data <STRING> (default: "")
 * 1: Use call instead of spawn <BOOL> (default: false)
 * 2: NetID of target to return data to <STRING> (default: "")
 *
 * Return Value:
 * N/A
 *
 * Examples:
 * ["dragonfly_db_fnc_test", false] call dragonfly_db_fnc_hashGetAll (Server or Singleplayer Only)
 * ["dragonfly_db_fnc_test", false, netId player] remoteExecCall ["dragonfly_db_fnc_hashGetAll", 2, false] (Multiplayer Only)
 *
 * Public: Yes
 */


params [["_function", "", [""]], ["_call", false, [false]], ["_netId", "", [""]]];

#ifdef __A3__DEBUG__
	diag_log text format ["ArmaDragonflyClient: 'dragonfly_db_fnc_hashGetAll' Function: '%1', Call: '%2', NetId: '%3'", _function, _call, _netId];
#endif

if (_function isEqualTo "") exitWith {
	diag_log text format ["ArmaDragonflyClient: 'dragonfly_db_fnc_hashGetAll' Invalid Input for Function '%1'", _function];
};

private _return = "";

if (_netId != "") then {
	#ifdef __A3__DEBUG__
		diag_log text format ["ArmaDragonflyClient: 'dragonfly_db_fnc_hashGetAll' Using NetId: '%1'", _netId];
	#endif

	if (_call) then {
		_return = "ArmaDragonflyClient" callExtension ["hgetall", [_function, _netId, _call]];
	} else {
		_return = "ArmaDragonflyClient" callExtension ["hgetall", [_function, _netId]];
	};
} else {
	#ifdef __A3__DEBUG__
		diag_log text "ArmaDragonflyClient: 'dragonfly_db_fnc_hashGetAll' Using current player";
	#endif

	if (_call) then {
		_return = "ArmaDragonflyClient" callExtension ["hgetall", [_function, _call]];
	} else {
		_return = "ArmaDragonflyClient" callExtension ["hgetall", [_function]];
	};
};

#ifdef __A3__DEBUG__
	diag_log text format ["ArmaDragonflyClient: 'dragonfly_db_fnc_hashGetAll' Return: '%1'", _return];
#endif

[(_return select 0)] call FUNC(scheduler);