#include "..\script_component.hpp"

/*
 * Function: dragonfly_db_fnc_hashGetAllId
 * Author: Creedcoder, J.Schmidt
 * Edit: 07.15.2024
 *
 * [Description]
 * Get all fields and values of hash stored at key from DB.
 *
 * Arguments:
 * 0: Name of stored key with hash <STRING> (default: "")
 * 1: Name of function to return data <STRING> (default: "")
 * 2: Use call instead of spawn <BOOL> (default: false)
 * 3: NetID of target to return data to <STRING> (default: "")
 *
 * Return Value:
 * N/A
 *
 * Examples:
 * [getPlayerUID player, "dragonfly_db_fnc_test", false] call dragonfly_db_fnc_hashGetAllId (Server or Singleplayer Only)
 * [getPlayerUID player, "dragonfly_db_fnc_test", false, netId player] remoteExecCall ["dragonfly_db_fnc_hashGetAllId", 2, false] (Multiplayer Only)
 *
 * Public: Yes
 */


params [["_key", "", [""]], ["_function", "", [""]], ["_call", false, [false]], ["_netId", "", [""]]];

#ifdef __A3__DEBUG__
	diag_log text format ["ArmaDragonflyClient: 'dragonfly_db_fnc_hashGetAllId' Key: '%1', Function: '%2', Call: '%3', NetId: '%4'", _key, _function, _call, _netId];
#endif

if (_key == "" || _function == "") exitWith {
	diag_log text format ["ArmaDragonflyClient: 'dragonfly_db_fnc_hashGetAllId' Invalid Input for Key '%1' or Function '%2'", _key, _function];
};

private _return = "";

if (_netId != "") then {
	#ifdef __A3__DEBUG__
		diag_log text format ["ArmaDragonflyClient: 'dragonfly_db_fnc_hashGetAllId' Using NetId: '%1'", _netId];
	#endif

	if (_call) then {
		_return = "ArmaDragonflyClient" callExtension ["hgetallid", [_key, _function, _netId, _call]];
	} else {
		_return = "ArmaDragonflyClient" callExtension ["hgetallid", [_key, _function, _netId]];
	};
} else {
	#ifdef __A3__DEBUG__
		diag_log text "ArmaDragonflyClient: 'dragonfly_db_fnc_hashGetAllId' Using current player";
	#endif

	if (_call) then {
		_return = "ArmaDragonflyClient" callExtension ["hgetallid", [_key, _function, _call]];
	} else {
		_return = "ArmaDragonflyClient" callExtension ["hgetallid", [_key, _function]];
	};
};

#ifdef __A3__DEBUG__
	diag_log text format ["ArmaDragonflyClient: 'dragonfly_db_fnc_hashGetAllId' Return: '%1'", _return];
#endif

[(_return select 0)] call FUNC(scheduler);