#include "script_component.hpp"

PREP_RECOMPILE_START;
#include "XEH_PREP.hpp"
PREP_RECOMPILE_END;

// private _category = [QUOTE(MOD_NAME), LLSTRING(displayName)];

[QGVAR(requestInitBank), {
    params [["_uid", "", [""]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID!" };
    GVAR(BankStore) call ["init", [_uid]];
}] call CFUNC(addEventHandler);

[QGVAR(requestHydrateBank), {
    params [["_uid", "", [""]], ["_mode", "bank", [""]], ["_resetAuthorization", false, [false]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID!" };
    GVAR(BankStore) call ["hydrateSession", [_uid, _mode, _resetAuthorization]];
}] call CFUNC(addEventHandler);

[QGVAR(requestGetBank), {
    params [["_uid", "", [""]], ["_field", "", [""]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID!" };

    private _finalData = GVAR(BankStore) call ["get", [GVAR(Registry), _uid, _field]];
    if (_field isNotEqualTo "") then {
        _finalData = createHashMapFromArray [[_field, _finalData]];
    };

    GVAR(BankMessenger) call ["sendAccountSync", [_uid, _finalData]];
}] call CFUNC(addEventHandler);

[QGVAR(requestSetBank), {
    params [["_uid", "", [""]], ["_field", "", [""]], ["_value", nil, [[], "", 0, false, createHashMap]], ["_sync", false, [false]]];

    if (_uid isEqualTo "" || _field isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID or Key!" };

    private _hashMap = GVAR(BankStore) call ["set", [GVAR(Registry), "bank:update", _uid, _field, _value, _sync]];
    GVAR(BankMessenger) call ["sendAccountSync", [_uid, _hashMap]];
}] call CFUNC(addEventHandler);

[QGVAR(requestMSetBank), {
    params [["_uid", "", [""]], ["_fieldValuePairs", createHashMap, [createHashMap]], ["_sync", false, [false]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID!" };
    if ((_fieldValuePairs isEqualTo createHashMap) || !(_fieldValuePairs isEqualType createHashMap)) exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid field pairs!" };

    private _hashMap = GVAR(BankStore) call ["mset", [GVAR(Registry), "bank:update", _uid, _fieldValuePairs, _sync]];
    GVAR(BankMessenger) call ["sendAccountSync", [_uid, _hashMap]];
}] call CFUNC(addEventHandler);

[QGVAR(requestSaveBank), {
    params [["_uid", "", [""]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID!" };

    private _finalData = GVAR(BankStore) call ["save", [GVAR(Registry), "bank:update", _uid]];
    GVAR(BankMessenger) call ["sendAccountSync", [_uid, _finalData]];
}] call CFUNC(addEventHandler);

[QGVAR(requestRemoveBank), {
    params [["_uid", "", [""]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID!" };
    GVAR(BankStore) call ["remove", [GVAR(Registry), _uid]];
}] call CFUNC(addEventHandler);

[QGVAR(requestDeposit), {
    params [["_uid", "", [""]], ["_amount", 0, [0]]];

    private _context = GVAR(BankValidator) call ["validateDeposit", [_uid, _amount]];
    if (_context isEqualTo false) exitWith {};
    GVAR(BankStore) call ["deposit", [_uid, _amount, _context]];
}] call CFUNC(addEventHandler);

[QGVAR(requestPayment), {
    params [["_uid", "", [""]], ["_amount", 0, [0]]];

    private _context = GVAR(BankValidator) call ["validatePayment", [_uid, _amount]];
    if (_context isEqualTo false) exitWith {};
    GVAR(BankStore) call ["payment", [_uid, _amount, _context]];
}] call CFUNC(addEventHandler);

[QGVAR(requestSubmitPin), {
    params [["_uid", "", [""]], ["_pin", "", [""]]];

    private _context = GVAR(BankValidator) call ["validateSubmitPin", [_uid, _pin]];
    if (_context isEqualTo false) exitWith {};
    GVAR(BankSessionManager) call ["submitPin", [_uid, _context]];
}] call CFUNC(addEventHandler);

[QGVAR(requestTransfer), {
    params [["_uid", "", [""]], ["_target", "", [""]], ["_from", "", [""]], ["_amount", 0, [0]]];

    private _context = GVAR(BankValidator) call ["validateTransfer", [_uid, _target, _from, _amount]];
    if (_context isEqualTo false) exitWith {};
    GVAR(BankStore) call ["transfer", [_uid, _target, _amount, _context]];
}] call CFUNC(addEventHandler);

[QGVAR(requestWithdraw), {
    params [["_uid", "", [""]], ["_amount", 0, [0]]];

    private _context = GVAR(BankValidator) call ["validateWithdraw", [_uid, _amount]];
    if (_context isEqualTo false) exitWith {};
    GVAR(BankStore) call ["withdraw", [_uid, _amount, _context]];
}] call CFUNC(addEventHandler);

[QGVAR(requestDepositEarnings), {
    params [["_uid", "", [""]], ["_amount", 0, [0]]];

    private _context = GVAR(BankValidator) call ["validateDepositEarnings", [_uid, _amount]];
    if (_context isEqualTo false) exitWith {};
    GVAR(BankStore) call ["depositEarnings", [_uid, _amount, _context]];
}] call CFUNC(addEventHandler);