#include "script_component.hpp"

PREP_RECOMPILE_START;
#include "XEH_PREP.hpp"
PREP_RECOMPILE_END;

call FUNC(initTaskStore);

[QGVAR(requestTaskCatalog), {
    params [["_uid", "", [""]]];

    if (_uid isEqualTo "") exitWith {
        ["WARNING", "Task catalog request received with empty UID."] call EFUNC(common,log);
    };

    private _player = [_uid] call EFUNC(common,getPlayer);
    if (_player isEqualTo objNull) exitWith {};

    [CRPC(cad,responseTaskCatalog), [GVAR(TaskStore) call ["getActiveTaskCatalog", []]], _player] call CFUNC(targetEvent);
}] call CFUNC(addEventHandler);

[QGVAR(requestAcceptTask), {
    params [["_uid", "", [""]], ["_taskID", "", [""]]];

    if (_uid isEqualTo "" || { _taskID isEqualTo "" }) exitWith {
        ["WARNING", "Invalid task accept request payload."] call EFUNC(common,log);
    };

    private _player = [_uid] call EFUNC(common,getPlayer);
    if (_player isEqualTo objNull) exitWith {};

    private _result = GVAR(TaskStore) call ["acceptTask", [_taskID, _uid]];
    [CRPC(cad,responseTaskAccept), [_result], _player] call CFUNC(targetEvent);
    [CRPC(cad,responseTaskCatalog), [GVAR(TaskStore) call ["getActiveTaskCatalog", []]], _player] call CFUNC(targetEvent);
}] call CFUNC(addEventHandler);