#include "script_component.hpp"

PREP_RECOMPILE_START;
#include "XEH_PREP.hpp"
PREP_RECOMPILE_END;

// private _category = [QUOTE(MOD_NAME), LLSTRING(displayName)];

[QGVAR(requestInitOrg), {
    params [["_uid", "", [""]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Org] Empty/Invalid UID!" };

    GVAR(OrgStore) call ["init", [_uid]];
}] call CFUNC(addEventHandler);

[QGVAR(requestCreateOrg), {
    params [["_uid", "", [""]], ["_orgName", "", [""]]];

    if (_uid isEqualTo "" || { _orgName isEqualTo "" }) exitWith {
        diag_log "[FORGE:Server:Org] Empty/Invalid UID or Organization Name!"
    };

    private _player = [_uid] call EFUNC(common,getPlayer);
    private _result = GVAR(OrgStore) call ["register", [_uid, _orgName]];

    if (_result getOrDefault ["success", false]) then {
        private _actorPatch = _result getOrDefault ["actorPatch", createHashMap];
        if (_actorPatch isNotEqualTo createHashMap) then {
            [CRPC(actor,responseSyncActor), [_actorPatch], _player] call CFUNC(targetEvent);
        };
    };

    [CRPC(org,responseCreateOrg), [_result], _player] call CFUNC(targetEvent);
}] call CFUNC(addEventHandler);

[QGVAR(requestGetOrg), {
    params [["_uid", "", [""]], ["_field", "", [""]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Org] Empty/Invalid UID!" };

    private _index = GVAR(IndexRegistry) get _uid;
    private _key = _index get "orgID";
    private _finalData = GVAR(OrgStore) call ["get", [GVAR(Registry), _key, _field]];
    private _player = [_uid] call EFUNC(common,getPlayer);

    [CRPC(org,responseSyncOrg), [_finalData], _player] call CFUNC(targetEvent);
}] call CFUNC(addEventHandler);

[QGVAR(requestSetOrg), {
    params [["_uid", "", [""]], ["_field", "", [""]], ["_value", nil, [[], "", 0, false, createHashMap]], ["_sync", false, [false]]];

    if (_uid isEqualTo "" || _field isEqualTo "") exitWith { diag_log "[FORGE:Server:Org] Empty/Invalid UID or Field!" };

    private _index = GVAR(IndexRegistry) get _uid;
    private _key = _index get "orgID";
    GVAR(OrgStore) call ["set", [GVAR(Registry), "org:update", _key, _field, _value, _sync]];
}] call CFUNC(addEventHandler);

[QGVAR(requestMSetOrg), {
    params [["_uid", "", [""]], ["_fieldValuePairs", createHashMap, [createHashMap]], ["_sync", false, [false]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Org] Empty/Invalid UID!" };
    if ((_fieldValuePairs isEqualTo createHashMap) || !(_fieldValuePairs isEqualType createHashMap)) exitWith { diag_log "[FORGE:Server:Org] Empty/Invalid field pairs!" };

    private _index = GVAR(IndexRegistry) get _uid;
    private _key = _index get "orgID";

    GVAR(OrgStore) call ["mset", [GVAR(Registry), "org:update", _key, _fieldValuePairs, _sync]];
}] call CFUNC(addEventHandler);

[QGVAR(requestSaveOrg), {
    params [["_uid", "", [""]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Org] Empty/Invalid UID!" };

    private _index = GVAR(IndexRegistry) get _uid;
    private _key = _index get "orgID";
    GVAR(OrgStore) call ["save", [GVAR(Registry), "org:update", _key]];
}] call CFUNC(addEventHandler);

[QGVAR(requestRemoveOrg), {
    params [["_uid", "", [""]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Org] Empty/Invalid UID!" };

    private _index = GVAR(IndexRegistry) get _uid;
    private _key = _index get "orgID";
    GVAR(OrgStore) call ["delete", [_key]];
}] call CFUNC(addEventHandler);

[QGVAR(requestLeaveOrg), {
    params [["_uid", "", [""]]];

    if (_uid isEqualTo "") exitWith {
        diag_log "[FORGE:Server:Org] Empty/Invalid UID for leave request!"
    };

    private _player = [_uid] call EFUNC(common,getPlayer);
    if (_player isEqualTo objNull) exitWith {};

    private _result = GVAR(OrgStore) call ["leave", [_uid]];
    if (_result getOrDefault ["success", false]) then {
        private _actorPatch = _result getOrDefault ["actorPatch", createHashMap];
        if (_actorPatch isNotEqualTo createHashMap) then {
            [CRPC(actor,responseSyncActor), [_actorPatch], _player] call CFUNC(targetEvent);
        };

        GVAR(OrgStore) call ["init", [_uid]];

        private _notificationParams = _result getOrDefault ["notification", []];
        if (_notificationParams isEqualType [] && { count _notificationParams > 0 }) then {
            [CRPC(notifications,recieveNotification), _notificationParams, _player] call CFUNC(targetEvent);
        };
    };

    [CRPC(org,responseLeaveOrg), [createHashMapFromArray [
        ["success", _result getOrDefault ["success", false]],
        ["message", _result getOrDefault ["message", "Unable to leave the organization."]]
    ]], _player] call CFUNC(targetEvent);
}] call CFUNC(addEventHandler);

[QGVAR(requestDisbandOrg), {
    params [["_uid", "", [""]]];

    if (_uid isEqualTo "") exitWith {
        diag_log "[FORGE:Server:Org] Empty/Invalid UID for disband request!"
    };

    private _requester = [_uid] call EFUNC(common,getPlayer);
    if (_requester isEqualTo objNull) exitWith {};

    private _result = GVAR(OrgStore) call ["disband", [_uid]];
    if !(_result getOrDefault ["success", false]) exitWith {
        [CRPC(org,responseDisbandOrg), [createHashMapFromArray [
            ["success", false],
            ["message", _result getOrDefault ["message", "Failed to disband organization."]],
            ["requester", true]
        ]], _requester] call CFUNC(targetEvent);
    };

    {
        [_x, _result] call {
            params [["_member", createHashMap, [createHashMap]], ["_disbandResult", createHashMap, [createHashMap]]];

            private _memberUid = _member getOrDefault ["uid", ""];
            if (_memberUid isEqualTo "") exitWith {};

            private _memberPlayer = [_memberUid] call EFUNC(common,getPlayer);
            if (_memberPlayer isEqualTo objNull) exitWith {};

            private _actorPatch = _member getOrDefault ["actorPatch", createHashMap];
            if (_actorPatch isNotEqualTo createHashMap) then {
                [CRPC(actor,responseSyncActor), [_actorPatch], _memberPlayer] call CFUNC(targetEvent);
            };

            GVAR(OrgStore) call ["init", [_memberUid]];
            [CRPC(org,responseDisbandOrg), [createHashMapFromArray [
                ["success", true],
                ["message", _member getOrDefault ["message", _disbandResult getOrDefault ["message", "Organization disbanded."]]],
                ["requester", _member getOrDefault ["requester", false]]
            ]], _memberPlayer] call CFUNC(targetEvent);

            private _notificationParams = _member getOrDefault ["notification", []];
            if (_notificationParams isEqualType [] && { count _notificationParams > 0 }) then {
                [CRPC(notifications,recieveNotification), _notificationParams, _memberPlayer] call CFUNC(targetEvent);
            };
        };
    } forEach (_result getOrDefault ["members", []]);
}] call CFUNC(addEventHandler);