#include "script_component.hpp"

if (isNil QGVAR(OrgClass)) then { call FUNC(initOrgClass); };

[QGVAR(initOrg), {
    GVAR(OrgClass) call ["init", []];
}] call CFUNC(addEventHandler);

[QGVAR(responseInitOrg), {
    params [["_data", createHashMap, [createHashMap]]];

    GVAR(OrgClass) call ["sync", [_data, true]];
}] call CFUNC(addEventHandler);

[QGVAR(responseSyncOrg), {
    params [["_data", createHashMap, [createHashMap]], ["_jip", false, [false]]];

    GVAR(OrgClass) call ["sync", [_data, _jip]];
}] call CFUNC(addEventHandler);

[QGVAR(responseCreateOrg), {
    params [["_payload", createHashMap, [createHashMap]]];

    private _control = uiNamespace getVariable [QGVAR(PendingBrowserControl), controlNull];
    uiNamespace setVariable [QGVAR(PendingBrowserControl), controlNull];

    private _success = _payload getOrDefault ["success", false];
    if (!_success) exitWith {
        if (_control isNotEqualTo controlNull) then {
            private _json = toJSON (createHashMapFromArray [
                ["message", _payload getOrDefault ["message", "Organization registration failed."]]
            ]);

            _control ctrlWebBrowserAction ["ExecJS", format ["OrgUIBridge.receiveCreateFailure(%1)", _json]];
        };
    };

    private _orgData = _payload getOrDefault ["org", createHashMap];
    GVAR(OrgClass) call ["sync", [_orgData, true]];

    if (_control isNotEqualTo controlNull) then {
        private _json = toJSON (GVAR(OrgClass) call ["buildPortalPayload", []]);
        _control ctrlWebBrowserAction ["ExecJS", format ["OrgUIBridge.receiveCreateSuccess(%1)", _json]];
    };
}] call CFUNC(addEventHandler);

[{
    EGVAR(actor,ActorClass) get "isLoaded";
}, {
    [QGVAR(initOrg), []] call CFUNC(localEvent);
}] call CFUNC(waitUntilAndExecute);