#include "script_component.hpp"

removeAllWeapons player;
removeAllAssignedItems player;
removeUniform player;
removeVest player;
removeBackpack player;
removeGoggles player;
removeHeadgear player;

SETPVAR(player,FORGE_actorIsLoaded,false);
cutText ["Loading In...", "BLACK", 1];

if (isNil QGVAR(ActorClass)) then { [] call FUNC(initActorClass); };

[QGVAR(initActor), {
    GVAR(ActorClass) call ["init", []];
}] call CFUNC(addEventHandler);

[QGVAR(responseInitActor), {
    params [["_data", createHashMap, [createHashMap]]];

    GVAR(ActorClass) call ["sync", [_data, true]];

    SETPVAR(player,FORGE_isLoaded,true);
    cutText ["", "PLAIN", 1];
}] call CFUNC(addEventHandler);

[QGVAR(responseSyncActor), {
    params [["_data", createHashMap, [createHashMap]], ["_jip", false, [false]]];

    GVAR(ActorClass) call ["sync", [_data, _jip]];
}] call CFUNC(addEventHandler);

[QGVAR(initActor), []] call CFUNC(localEvent);

[{
    GETVAR(player,FORGE_actorIsLoaded,false)
}, {
    private _holster = GVAR(ActorClass) call ["get", ["holster", true]];
    if (_holster) then { [player] call AFUNC(weaponselect,putWeaponAway); };
}] call CFUNC(waitUntilAndExecute);