#include "script_component.hpp"

PREP_RECOMPILE_START;
#include "XEH_PREP.hpp"
PREP_RECOMPILE_END;

// private _category = [QUOTE(MOD_NAME), LLSTRING(displayName)];

if (isNil QGVAR(BankStore)) then { [] call FUNC(initBankStore); };

[QGVAR(requestInitBank), {
    params [["_uid", "", [""]], ["_bank", createHashMap, [createHashMap]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID!" };
    if (_bank isEqualTo createHashMap) exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid Bank data!" };

    GVAR(BankStore) call ["init", [_uid, _bank]];
}] call CFUNC(addEventHandler);

[QGVAR(requestGetBank), {
    params [["_uid", "", [""]], ["_sync", false, [false]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID!" };

    private _session = EGVAR(actor,PlayerSessions) getOrDefault [_uid, nil];
    if (isNil "_session") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid Session!" };

    GVAR(BankStore) call ["get", [_uid, _sync]];
}] call CFUNC(addEventHandler);

[QGVAR(requestSetBank), {
    params [["_uid", "", [""]], ["_key", "", [""]], ["_value", nil, [[], "", 0, false, createHashMap]], ["_sync", false, [false]]];

    if (_uid isEqualTo "" || _key isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID or Key!" };

    private _session = EGVAR(actor,PlayerSessions) getOrDefault [_uid, nil];
    if (isNil "_session") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid Session!" };

    GVAR(BankStore) call ["set", [_uid, _key, _value, _sync]];
}] call CFUNC(addEventHandler);

[QGVAR(requestMSetBank), {
    params [["_uid", "", [""]], ["_fieldValuePairs", createHashMap, [createHashMap]], ["_sync", false, [false]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID!" };
    if ((_fieldValuePairs isEqualTo createHashMap) || !(_fieldValuePairs isEqualType createHashMap)) exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid field pairs!" };

    private _session = EGVAR(actor,PlayerSessions) getOrDefault [_uid, nil];
    if (isNil "_session") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid Session!" };

    GVAR(BankStore) call ["mset", [_uid, _fieldValuePairs, _sync]];
}] call CFUNC(addEventHandler);

[QGVAR(requestSaveBank), {
    params [["_uid", "", [""]], ["_sync", false, [false]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID!" };

    private _session = EGVAR(actor,PlayerSessions) getOrDefault [_uid, nil];
    if (isNil "_session") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid Session!" };

    GVAR(BankStore) call ["save", [_uid, _sync]];
}] call CFUNC(addEventHandler);

[QGVAR(requestRemoveBank), {
    params [["_uid", "", [""]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid UID!" };

    GVAR(BankStore) call ["remove", [_uid]];
}] call CFUNC(addEventHandler);

[QGVAR(requestResync), {
    params ["_player"];

    private _uid = getPlayerUID _player;
    private _bank = GVAR(BankStore) call ["get", [_uid, true]];

    private _session = EGVAR(actor,PlayerSessions) getOrDefault [_uid, nil];
    if (isNil "_session") exitWith { diag_log "[FORGE:Server:Bank] Empty/Invalid Session!" };

    [CRPC(bank,responseSyncBank), [_bank, true], _player] call CFUNC(targetEvent);

    diag_log format ["[FORGE:Server:Bank] Resync completed for %1", _uid];
}] call CFUNC(addEventHandler);