#include "..\script_component.hpp"

/*
 * File: fnc_initOrgClass.sqf
 * Author: IDSolutions
 * Date: 2026-02-13
 * Last Update: 2026-02-13
 * Public: No
 *
 * Description:
 * Initializes the org class.
 *
 * Arguments:
 * None
 *
 * Return Value:
 * Org class object [HASHMAP OBJECT]
 *
 * Examples:
 * call forge_client_org_fnc_initOrgClass
 */

#pragma hemtt ignore_variables ["_self"]
GVAR(OrgBaseClass) = compileFinal createHashMapFromArray [
    ["#type", "OrgBaseClass"],
    ["#create", compileFinal {
        _self set ["uid", getPlayerUID player];
        _self set ["org", createHashMap];
        _self set ["isLoaded", false];
        _self set ["lastSave", time];

        private _org = createHashMap;
        _org set ["id", ""];
        _org set ["owner", ""];
        _org set ["name", ""];
        _org set ["funds", 0];
        _org set ["reputation", 0];
        _org set ["assets", createHashMap];
        _org set ["members", createHashMap];

        _self set ["org", _org];
    }],
    ["init", compileFinal {
        private _uid = _self get "uid";
        private _org = _self get "org";

        [SRPC(org,requestInitOrg), [_uid, _org]] call CFUNC(serverEvent);

        systemChat format ["Org loaded for %1", (name player)];
        diag_log "[FORGE:Client:Org] Org Class Initialized!";
    }],
    ["save", compileFinal {
        params [["_sync", false, [false]]];

        private _uid = _self get "uid";
        [SRPC(org,requestSaveOrg), [_uid, _sync]] call CFUNC(serverEvent);

        _self set ["lastSave", time];
    }],
    ["sync", compileFinal {
        params [["_data", createHashMap, [createHashMap]], ["_jip", false, [false]]];

        private _isLoaded = _self get "isLoaded";
        private _org = _self get "org";

        { _org set [_x, _y]; } forEach _data;
        _self set ["org", _org];

        if !(_isLoaded) then { _self set ["isLoaded", true]; };
        diag_log "[FORGE:Client:Org] Sync completed";
    }],
    ["get", compileFinal {
        params [["_key", "", [""]], ["_default", nil, [[], "", 0, false, createHashMap]]];

        private _org = _self get "org";
        _org getOrDefault [_key, _default];
    }]
];

GVAR(OrgClass) = createHashMapObject [GVAR(OrgBaseClass)];
GVAR(OrgClass)