#include "..\script_component.hpp"

/*
 * File: fnc_initClass.sqf
 * Author: IDSolutions
 * Public: No
 *
 * Description:
 * Initializes the bank class for lifecycle and save helpers.
 */

#pragma hemtt ignore_variables ["_self"]
GVAR(BankBaseClass) = compileFinal createHashMapFromArray [
    ["#type", "BankBaseClass"],
    ["#create", compileFinal {
        _self set ["uid", getPlayerUID player];
        _self set ["isLoaded", false];
        _self set ["lastSave", time];
    }],
    ["init", compileFinal {
        [SRPC(bank,requestInitBank), [getPlayerUID player]] call CFUNC(serverEvent);
        _self set ["lastSave", time];

        systemChat format ["Bank loaded for %1", (name player)];
        diag_log "[FORGE:Client:Bank] Bank Class Initialized!";
    }],
    ["markLoaded", compileFinal {
        if !(_self getOrDefault ["isLoaded", false]) then { _self set ["isLoaded", true]; };

        true
    }],
    ["save", compileFinal {
        [SRPC(bank,requestSaveBank), [getPlayerUID player]] call CFUNC(serverEvent);
        _self set ["lastSave", time];
    }]
];

GVAR(BankClass) = createHashMapObject [GVAR(BankBaseClass)];
GVAR(BankClass)