#include "..\script_component.hpp"

/*
 * File: fnc_initClass.sqf
 * Author: IDSolutions
 * Date: 2026-03-25
 * Last Update: 2026-03-25
 * Public: No
 *
 * Description:
 *     No description added yet.
 *
 * Parameter(s):
 *     N/A
 *
 * Returns:
 *     Something [BOOL]
 *
 * Example(s):
 *     [parameter] call forge_x_component_fnc_myFunction
 */

#pragma hemtt ignore_variables ["_self"]
GVAR(OrgBaseClass) = compileFinal createHashMapFromArray [
    ["#type", "OrgBaseClass"],
    ["#create", compileFinal {
        _self set ["uid", getPlayerUID player];
        _self set ["isLoaded", false];
        _self set ["lastSave", time];
    }],
    ["init", compileFinal {
        [SRPC(org,requestInitOrg), [getPlayerUID player]] call CFUNC(serverEvent);
        _self set ["lastSave", time];

        systemChat format ["Org loaded for %1", (name player)];
        diag_log "[FORGE:Client:Org] Org Class Initialized!";
    }],
    ["markLoaded", compileFinal {
        if !(_self getOrDefault ["isLoaded", false]) then { _self set ["isLoaded", true]; };

        true
    }],
    ["save", compileFinal {
        [SRPC(bank,requestSaveOrg), [getPlayerUID player]] call CFUNC(serverEvent);
        _self set ["lastSave", time];
    }]
];

GVAR(OrgClass) = createHashMapObject [GVAR(OrgBaseClass)];
GVAR(OrgClass)