#include "script_component.hpp"

PREP_RECOMPILE_START;
#include "XEH_PREP.hpp"
PREP_RECOMPILE_END;

// private _category = [QUOTE(MOD_NAME), LLSTRING(displayName)];

[QGVAR(requestInitActor), {
    params [["_uid", "", [""]], ["_actor", createHashMap, [createHashMap]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid UID!" };
    if (_actor isEqualTo createHashMap) exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid Actor data!" };

    GVAR(ActorStore) call ["init", [_uid, _actor]];
}] call CFUNC(addEventHandler);

[QGVAR(requestGetActor), {
    params [["_uid", "", [""]], ["_sync", false, [false]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid UID!" };

    private _session = GVAR(PlayerSessions) getOrDefault [_uid, nil];
    if (isNil "_session") exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid Session!" };

    GVAR(ActorStore) call ["get", [_uid, _sync]];
}] call CFUNC(addEventHandler);

[QGVAR(requestSetActor), {
    params [["_uid", "", [""]], ["_key", "", [""]], ["_value", nil, [[], "", 0, false, createHashMap]], ["_sync", false, [false]]];

    if (_uid isEqualTo "" || _key isEqualTo "") exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid UID or Key!" };

    private _session = GVAR(PlayerSessions) getOrDefault [_uid, nil];
    if (isNil "_session") exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid Session!" };

    GVAR(ActorStore) call ["set", [_uid, _key, _value, _sync]];
}] call CFUNC(addEventHandler);

[QGVAR(requestMSetActor), {
    params [["_uid", "", [""]], ["_fieldValuePairs", createHashMap, [createHashMap]], ["_sync", false, [false]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid UID!" };
    if ((_fieldValuePairs isEqualTo createHashMap) || !(_fieldValuePairs isEqualType createHashMap)) exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid field pairs!" };

    private _session = GVAR(PlayerSessions) getOrDefault [_uid, nil];
    if (isNil "_session") exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid Session!" };

    GVAR(ActorStore) call ["mset", [_uid, _fieldValuePairs, _sync]];
}] call CFUNC(addEventHandler);

[QGVAR(requestSaveActor), {
    params [["_uid", "", [""]], ["_sync", false, [false]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid UID!" };

    private _session = GVAR(PlayerSessions) getOrDefault [_uid, nil];
    if (isNil "_session") exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid Session!" };

    GVAR(ActorStore) call ["save", [_uid, _sync]];
}] call CFUNC(addEventHandler);

[QGVAR(requestRemoveActor), {
    params [["_uid", "", [""]]];

    if (_uid isEqualTo "") exitWith { diag_log "[FORGE:Server:Actor] Empty/Invalid UID!" };

    GVAR(ActorStore) call ["remove", [_uid]];
}] call CFUNC(addEventHandler);