07d5422091
- Updated fnc_extCall.sqf to suppress logging for specific functions. - Added object model prototypes for task instances in prototypes/taskObjectPrototypes.sqf. - Enhanced README.md to document the new object model and its purpose. - Modified XEH_postInit.sqf to improve event handling for defuse tasks. - Updated various task functions (fnc_attack, fnc_defend, fnc_defuse, fnc_delivery, fnc_destroy, fnc_heartBeat, fnc_hostage, fnc_hvt) to include task acceptance checks. - Improved fnc_makeHostage and fnc_makeIED to ensure proper task registration and state management. - Introduced new methods in task object prototypes for better state management and task flow control.
78 lines
1.9 KiB
Plaintext
78 lines
1.9 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* Author: IDSolutions
|
|
* Registers Entity and starts heartbeat
|
|
*
|
|
* Arguments:
|
|
* 0: The entity <OBJECT>
|
|
* 1: Type of the entity <STRING>
|
|
* 2: The countdown timer <NUMBER>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [_entity, "entity_type", 30] spawn FUNC(heartBeat);
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
params [["_entity", nil, [objNull, 0, [], sideUnknown, grpNull, ""]], ["_typeOf", "", [""]], ["_time", 0, [0]]];
|
|
|
|
private _nearPlayers = [];
|
|
|
|
switch (_typeOf) do {
|
|
case "hostage": {
|
|
_entity setCaptive true;
|
|
_entity enableAIFeature ["MOVE", false];
|
|
_entity playMove "acts_executionvictim_loop";
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
_nearPlayers = allPlayers inAreaArray [ASLToAGL getPosASL _entity, 2, 2, 0, false, 2];
|
|
count _nearPlayers > 0
|
|
};
|
|
|
|
private _nearPlayer = _nearPlayers select 0;
|
|
|
|
[_entity] joinSilent (group _nearPlayer);
|
|
|
|
// Keep rescued hostages protected while they follow the player group.
|
|
_entity setCaptive true;
|
|
_entity enableAIFeature ["MOVE", true];
|
|
_entity playMove "acts_executionvictim_unbow";
|
|
};
|
|
case "hvt": {
|
|
waitUntil {
|
|
sleep 1;
|
|
_nearPlayers = allPlayers inAreaArray [ASLToAGL getPosASL _entity, 2, 2, 0, false, 2];
|
|
count _nearPlayers > 0
|
|
};
|
|
|
|
_entity setCaptive true;
|
|
doStop _entity;
|
|
};
|
|
case "ied": {
|
|
private _taskID = _entity getVariable ["assignedTask", ""];
|
|
if (_taskID isNotEqualTo "") then {
|
|
waitUntil {
|
|
sleep 1;
|
|
GVAR(TaskStore) call ["isTaskAccepted", [_taskID]]
|
|
};
|
|
};
|
|
|
|
while { alive _entity && _time > 0} do {
|
|
if (_time > 10) then { _entity say3D "FORGE_timerBeep" };
|
|
if (_time <= 10 && _time > 5) then { _entity say3D "FORGE_timerBeepShort" };
|
|
if (_time <= 5) then { _entity say3D "FORGE_timerEnd" };
|
|
if (_time <= 0) exitWith { _entity setDamage 1 };
|
|
|
|
_time = _time -1;
|
|
sleep 1;
|
|
};
|
|
|
|
if (alive _entity && _time <= 0) then { _entity setDamage 1 };
|
|
};
|
|
};
|