Jacob Schmidt
ff7ff0c4e5
## Summary This finishes the org credit line workflow so it behaves like reserved treasury-backed credit instead of a simple member allowance. ## What changed - reserve org funds immediately when a credit line is assigned - track credit lines with: - approved amount - available amount - outstanding principal - interest rate - amount due - consume reserved credit during store checkout without charging org funds a second time - add credit line repayment through the bank app - sync richer credit line state into org and bank payloads/UI - keep legacy `amount` compatibility mapped to available credit for older consumers ## User-facing behavior - assigning a credit line now reduces available org funds immediately - spending on `credit_line` reduces available credit and creates debt with interest - the bank app now shows outstanding credit debt and allows repayment from personal bank funds - the org treasury view now shows reserved credit and outstanding due totals ## Validation - `cargo fmt` - `npm run build:webui` - `cargo test -p forge-services --quiet` - `cargo test -p forge-server --quiet` ## Follow-up checks - validate in-game that assigning a credit line reduces org funds immediately - validate store checkout with `credit_line` updates available credit and debt correctly - validate bank repayment decreases player bank balance, increases org funds, and reduces amount due Co-authored-by: Jacob Schmidt <innovativestudios@outlook.com> Reviewed-on: #2
42 lines
1.4 KiB
Plaintext
42 lines
1.4 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* Author: IDSolutions
|
|
* Assigns cargo to a task for delivery
|
|
*
|
|
* Arguments:
|
|
* 0: Object to convert to delivery cargo <OBJECT>
|
|
* 1: Task ID to assign the cargo to <STRING>
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* [_cargoObject, "delivery_1"] call forge_server_task_fnc_makeCargo;
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
params [["_cargo", objNull, [objNull]], ["_taskID", "", [""]]];
|
|
|
|
["INFO", format ["Make Cargo: %1", _this]] call EFUNC(common,log);
|
|
|
|
if (isNull _cargo) exitWith { ["ERROR", "Attempt to create cargo from null object"] call EFUNC(common,log); };
|
|
if (_taskID == "") exitWith { ["ERROR", "No task ID provided for cargo"] call EFUNC(common,log); };
|
|
|
|
SETPVAR(_cargo,assignedTask,_taskID);
|
|
GVAR(TaskStore) call ["registerTaskEntity", ["cargo", _taskID, _cargo]];
|
|
|
|
_cargo addEventHandler ["Dammaged", {
|
|
params ["_unit", "_hitSelection", "_damage", "_hitPartIndex", "_hitPoint", "_shooter", "_projectile"];
|
|
|
|
if (damage _unit >= 0.7) then {
|
|
private _taskID = GETVAR(_unit,assignedTask,"");
|
|
if (_taskID isEqualTo "") exitWith {};
|
|
if (_unit getVariable [QGVAR(cargoDamageWarned), false]) exitWith {};
|
|
|
|
_unit setVariable [QGVAR(cargoDamageWarned), true];
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "warning", "Tasks", format ["Cargo for task %1 has been severely damaged.", _taskID]]];
|
|
};
|
|
}];
|