45a4f7460a
- add the imported server task addon to the current framework with task ownership, task catalog, mission-manager attack generation, org-owned reward routing, participant notifications, and reputation syncing - restructure org persistence so core org data, assets, fleet, and members are handled through the current Redis/extension model with matching Rust repository and service updates - wire the client CAD addon into the framework, actor device action, shared web UI bridge pattern, and task listing/acceptance flow - add a source-driven CAD web UI layout with ui.config.mjs and extend the shared web UI builder to support custom HTML template pages for multi-surface UIs
115 lines
4.1 KiB
Plaintext
115 lines
4.1 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* Author: IDSolutions
|
|
* Registers an destroy task
|
|
*
|
|
* Arguments:
|
|
* 0: ID of the task <STRING>
|
|
* 1: Amount of targets escaped to fail the task <NUMBER>
|
|
* 2: Amount of targets eliminated to complete the task <NUMBER>
|
|
* 3: Amount of funds the company recieves if the task is successful <NUMBER> (default: 0)
|
|
* 4: Amount of rating the company and player lose if the task is failed <NUMBER> (default: 0)
|
|
* 5: Amount of rating the company and player recieve if the task is successful <NUMBER> (default: 0)
|
|
* 6: Should the mission end (MissionSuccess) if the task is successful <BOOL> (default: false)
|
|
* 7: Should the mission end (MissionFailed) if the task is failed <BOOL> (default: false)
|
|
* 8: Amount of time before target(s) escape <NUMBER> (default: -1)
|
|
* 9: Equipment rewards <ARRAY> (default: [])
|
|
* 10: Supply rewards <ARRAY> (default: [])
|
|
* 11: Weapon rewards <ARRAY> (default: [])
|
|
* 12: Vehicle rewards <ARRAY> (default: [])
|
|
* 13: Special rewards <ARRAY> (default: [])
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* ["task_name", 1, 2, 250000, -75, 300, false, false] spawn forge_server_task_fnc_destroy;
|
|
* ["task_name", 1, 2, 250000, -75, 300, false, false, 45] spawn forge_server_task_fnc_destroy;
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
params [
|
|
["_taskID", "", [""]],
|
|
["_limitFail", -1, [0]],
|
|
["_limitSuccess", -1, [0]],
|
|
["_companyFunds", 0, [0]],
|
|
["_ratingFail", 0, [0]],
|
|
["_ratingSuccess", 0, [0]],
|
|
["_endSuccess", false, [false]],
|
|
["_endFail", false, [false]],
|
|
["_time", -1, [0]],
|
|
["_equipmentRewards", [], [[]]],
|
|
["_supplyRewards", [], [[]]],
|
|
["_weaponRewards", [], [[]]],
|
|
["_vehicleRewards", [], [[]]],
|
|
["_specialRewards", [], [[]]]
|
|
];
|
|
|
|
private _result = 0;
|
|
private _targets = [];
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
_targets = GVAR(TaskStore) call ["getTaskEntities", ["targets", _taskID]];
|
|
GVAR(TaskStore) call ["trackParticipants", [_taskID, _targets, "", 300]];
|
|
count _targets > 0
|
|
};
|
|
|
|
_targets = GVAR(TaskStore) call ["getTaskEntities", ["targets", _taskID]];
|
|
private _startTime = if (!isNil "_time") then { floor(time) } else { nil };
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
GVAR(TaskStore) call ["trackParticipants", [_taskID, _targets, "", 300]];
|
|
|
|
private _targetsDestroyed = ({ !alive _x } count _targets);
|
|
|
|
if (!isNil "_time") then {
|
|
private _timeExpired = (floor time - _startTime >= _time);
|
|
|
|
if (_targetsDestroyed < _limitSuccess && _timeExpired) then { _result = 1; };
|
|
|
|
(_result == 1) or (_targetsDestroyed >= _limitSuccess)
|
|
} else {
|
|
(_targetsDestroyed >= _limitSuccess)
|
|
};
|
|
};
|
|
|
|
if (_result == 1) then {
|
|
{ deleteVehicle _x } forEach _targets;
|
|
|
|
[_taskID, "FAILED"] call BFUNC(taskSetState);
|
|
|
|
sleep 1;
|
|
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "warning", "Tasks", format ["Task failed: %1 reputation", _ratingFail]]];
|
|
GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingFail]];
|
|
GVAR(TaskStore) call ["clearTask", [_taskID]];
|
|
|
|
if (_endFail) then { ["MissionFail", false] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
|
|
} else {
|
|
{ deleteVehicle _x } forEach _targets;
|
|
|
|
private _rewards = createHashMap;
|
|
_rewards set ["funds", _companyFunds];
|
|
|
|
if (_equipmentRewards isNotEqualTo []) then { _rewards set ["equipment", _equipmentRewards]; };
|
|
if (_supplyRewards isNotEqualTo []) then { _rewards set ["supplies", _supplyRewards]; };
|
|
if (_weaponRewards isNotEqualTo []) then { _rewards set ["weapons", _weaponRewards]; };
|
|
if (_vehicleRewards isNotEqualTo []) then { _rewards set ["vehicles", _vehicleRewards]; };
|
|
if (_specialRewards isNotEqualTo []) then { _rewards set ["special", _specialRewards]; };
|
|
|
|
[_taskID, _rewards] call FUNC(handleTaskRewards);
|
|
[_taskID, "SUCCEEDED"] call BFUNC(taskSetState);
|
|
|
|
sleep 1;
|
|
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "success", "Tasks", format ["Task completed: %1 reputation, $%2 funds", _ratingSuccess, [_companyFunds] call EFUNC(common,formatNumber)]]];
|
|
GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingSuccess]];
|
|
GVAR(TaskStore) call ["clearTask", [_taskID]];
|
|
|
|
if (_endSuccess) then { ["MissionSuccess", true] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
|
|
};
|