70 lines
1.9 KiB
Plaintext
70 lines
1.9 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* File: fnc_initBankClass.sqf
|
|
* Author: IDSolutions
|
|
* Date: 2025-12-16
|
|
* Last Update: 2026-02-13
|
|
* Public: No
|
|
*
|
|
* Description:
|
|
* Initializes the bank class.
|
|
*
|
|
* Arguments:
|
|
* None
|
|
*
|
|
* Return Value:
|
|
* Bank class object [HASHMAP OBJECT]
|
|
*
|
|
* Example:
|
|
* call forge_client_bank_fnc_initBankClass
|
|
*/
|
|
|
|
#pragma hemtt ignore_variables ["_self"]
|
|
GVAR(BankBaseClass) = compileFinal createHashMapFromArray [
|
|
["#type", "BankBaseClass"],
|
|
["#create", compileFinal {
|
|
_self set ["uid", getPlayerUID player];
|
|
_self set ["account", createHashMap];
|
|
_self set ["isLoaded", false];
|
|
_self set ["lastSave", time];
|
|
}],
|
|
["init", compileFinal {
|
|
private _uid = _self get "uid";
|
|
|
|
[SRPC(bank,requestInitBank), [_uid]] call CFUNC(serverEvent);
|
|
|
|
systemChat format ["Bank loaded for %1", (name player)];
|
|
diag_log "[FORGE:Client:Bank] Bank Class Initialized!";
|
|
}],
|
|
["save", compileFinal {
|
|
params [["_sync", false, [false]]];
|
|
|
|
private _uid = _self get "uid";
|
|
[SRPC(bank,requestSaveBank), [_uid, _sync]] call CFUNC(serverEvent);
|
|
|
|
_self set ["lastSave", time];
|
|
}],
|
|
["sync", compileFinal {
|
|
params [["_data", createHashMap, [createHashMap]], ["_jip", false, [false]]];
|
|
|
|
private _account = _self get "account";
|
|
private _isLoaded = _self get "isLoaded";
|
|
|
|
{ _account set [_x, _y]; } forEach _data;
|
|
_self set ["account", _account];
|
|
|
|
if !(_isLoaded) then { _self set ["isLoaded", true]; };
|
|
diag_log "[FORGE:Client:Bank] Sync completed";
|
|
}],
|
|
["get", compileFinal {
|
|
params [["_key", "", [""]], ["_default", nil, [[], "", 0, false, createHashMap]]];
|
|
|
|
private _account = _self get "account";
|
|
_account getOrDefault [_key, _default];
|
|
}]
|
|
];
|
|
|
|
GVAR(BankClass) = createHashMapObject [GVAR(BankBaseClass)];
|
|
GVAR(BankClass)
|