forge/arma/server/addons/locker/functions/fnc_initVAStore.sqf

#include "..\script_component.hpp"

/*
 * File: fnc_initVAStore.sqf
 * Author: IDSolutions
 * Date: 2025-12-17
 * Last Update: 2026-04-01
 * Public: No
 *
 * Description:
 * Initializes the Virtual Arsenal store for managing player arsenal unlocks.
 * Virtual arsenal hot state is owned by the extension; SQF acts as a thin bridge.
 *
 * Arguments:
 * None
 *
 * Return Value:
 * VA store object [HASHMAP OBJECT]
 *
 * Example:
 * call forge_server_locker_fnc_initVAStore
 */

#pragma hemtt ignore_variables ["_self"]
GVAR(VArsenalModel) = compileFinal createHashMapObject [[
    ["#type", "VArsenalModel"],
    ["defaults", compileFinal {
        private _vArsenal = createHashMap;

        _vArsenal set ["backpacks", ["B_AssaultPack_rgr"]];
        _vArsenal set ["items", ["FirstAidKit", "G_Combat", "H_Cap_blk_ION", "H_HelmetB", "ItemCompass", "ItemGPS", "ItemMap", "ItemRadio", "ItemWatch", "U_IG_Guerrilla_6_1", "V_TacVest_oli", "ACE_EarPlugs"]];
        _vArsenal set ["magazines", ["16Rnd_9x21_Mag", "30Rnd_65x39_caseless_black_mag", "Chemlight_blue", "Chemlight_green", "Chemlight_red", "Chemlight_yellow", "HandGrenade", "SmokeShell", "SmokeShellBlue", "SmokeShellGreen", "SmokeShellOrange", "SmokeShellPurple", "SmokeShellRed", "SmokeShellYellow"]];
        _vArsenal set ["weapons", ["arifle_MX_F", "hgun_P07_F"]];

        _vArsenal
    }]
]];

GVAR(VABaseStore) = compileFinal createHashMapFromArray [
    ["#base", EGVAR(common,BaseStore)],
    ["#type", "VABaseStore"],
    ["#create", compileFinal {
        ["INFO", "VArsenal Store Initialized!"] call EFUNC(common,log);
    }],
    ["callHotVArsenal", compileFinal {
        params [["_function", "", [""]], ["_arguments", [], [[]]]];

        if (_function isEqualTo "") exitWith { createHashMap };

        [_function, _arguments] call EFUNC(extension,extCall) params ["_result", "_isSuccess"];
        if !(_isSuccess) exitWith { createHashMap };
        if !(_result isEqualType "") exitWith { createHashMap };
        if ((_result find "Error:") == 0) exitWith {
            ["ERROR", format ["VArsenal extension call '%1' failed: %2", _function, _result]] call EFUNC(common,log);
            createHashMap
        };

        private _data = fromJSON _result;
        if !(_data isEqualType createHashMap) exitWith { createHashMap };
        _data
    }],
    ["loadHotVArsenal", compileFinal {
        params [["_uid", "", [""]], ["_initialize", false, [false]]];

        if (_uid isEqualTo "") exitWith { createHashMap };

        private _command = ["owned:locker:hot:fetch", "owned:locker:hot:init"] select _initialize;
        _self call ["callHotVArsenal", [_command, [_uid]]]
    }],
    ["init", compileFinal {
        params [["_uid", "", [""]]];

        private _player = [_uid] call EFUNC(common,getPlayer);
        if (isNull _player) exitWith { createHashMap };

        private _arsenal = _self call ["loadHotVArsenal", [_uid, true]];
        if (_arsenal isEqualTo createHashMap) then {
            _arsenal = GVAR(VArsenalModel) call ["defaults", []];
            ["ERROR", format ["Failed to initialize virtual arsenal for %1! Using fallback virtual arsenal.", _uid]] call EFUNC(common,log);
        };

        [CRPC(locker,responseInitVA), [_arsenal], _player] call CFUNC(targetEvent);
        _arsenal
    }],
    ["get", compileFinal {
        params [["_uid", "", [""]], ["_field", "", [""]]];

        private _arsenal = _self call ["loadHotVArsenal", [_uid, false]];
        if (_arsenal isEqualTo createHashMap) then {
            _arsenal = _self call ["loadHotVArsenal", [_uid, true]];
        };

        if (_field isEqualTo "") exitWith { _arsenal };
        _arsenal getOrDefault [_field, []]
    }],
    ["override", compileFinal {
        params [
            ["_uid", "", [""]],
            ["_data", createHashMap, [createHashMap]],
            ["_save", false, [false]]
        ];

        if (_uid isEqualTo "") exitWith { createHashMap };
        if !(_data isEqualType createHashMap) exitWith { createHashMap };

        private _arsenal = _self call ["callHotVArsenal", ["owned:locker:hot:override", [_uid, toJSON _data]]];
        if (_save && { _arsenal isNotEqualTo createHashMap }) then {
            private _savedArsenal = _self call ["callHotVArsenal", ["owned:locker:hot:save", [_uid]]];
            if (_savedArsenal isNotEqualTo createHashMap) then {
                _arsenal = _savedArsenal;
            } else {
                _arsenal = createHashMap;
            };
        };

        _arsenal
    }],
    ["set", compileFinal {
        params [
            ["_uid", "", [""]],
            ["_field", "", [""]],
            ["_value", nil, [[], "", 0, false, createHashMap]],
            ["_sync", false, [false]]
        ];

        if (_uid isEqualTo "" || { _field isEqualTo "" }) exitWith { createHashMap };

        private _arsenal = _self call ["get", [_uid, ""]];
        if !(_arsenal isEqualType createHashMap) exitWith { createHashMap };

        _arsenal set [_field, _value];
        private _updatedArsenal = _self call ["override", [_uid, _arsenal, _sync]];
        if !(_updatedArsenal isEqualType createHashMap) exitWith { createHashMap };
        if (_updatedArsenal isEqualTo createHashMap) exitWith { createHashMap };

        createHashMapFromArray [[_field, _updatedArsenal getOrDefault [_field, _value]]]
    }],
    ["mset", compileFinal {
        params [
            ["_uid", "", [""]],
            ["_fieldValuePairs", createHashMap, [createHashMap]],
            ["_sync", false, [false]]
        ];

        if (_uid isEqualTo "") exitWith { createHashMap };
        if !(_fieldValuePairs isEqualType createHashMap) exitWith { createHashMap };

        private _arsenal = _self call ["get", [_uid, ""]];
        if !(_arsenal isEqualType createHashMap) exitWith { createHashMap };

        { _arsenal set [_x, _y]; } forEach _fieldValuePairs;
        private _updatedArsenal = _self call ["override", [_uid, _arsenal, _sync]];
        if !(_updatedArsenal isEqualType createHashMap) exitWith { createHashMap };
        if (_updatedArsenal isEqualTo createHashMap) exitWith { createHashMap };

        +_fieldValuePairs
    }],
    ["save", compileFinal {
        params [["_uid", "", [""]]];

        if (_uid isEqualTo "") exitWith { createHashMap };
        _self call ["callHotVArsenal", ["owned:locker:hot:save", [_uid]]]
    }],
    ["remove", compileFinal {
        params [["_uid", "", [""]]];

        if (_uid isEqualTo "") exitWith { false };

        ["owned:locker:hot:remove", [_uid]] call EFUNC(extension,extCall) params ["_result", "_isSuccess"];
        _isSuccess && { _result isEqualTo "OK" }
    }],
    ["unlockItems", compileFinal {
        params [["_uid", "", [""]], ["_items", [], [[]]], ["_commit", false, [false]]];

        private _result = createHashMapFromArray [
            ["success", false],
            ["message", "VA unlock failed."],
            ["patch", createHashMap],
            ["arsenal", createHashMap]
        ];

        private _arsenal = +(_self call ["get", [_uid, ""]]);
        if (_arsenal isEqualTo createHashMap) then {
            _arsenal = GVAR(VArsenalModel) call ["defaults", []];
        };
        private _patch = createHashMap;
        private _categoriesToSync = [];

        {
            private _item = _x;
            private _className = _item getOrDefault ["classname", ""];
            private _category = toLowerANSI (_item getOrDefault ["category", ""]);
            private _arsenalCategory = switch (_category) do {
                case "item": { "items" };
                case "weapon": { "weapons" };
                case "magazine": { "magazines" };
                case "backpack": { "backpacks" };
                default { "items" };
            };

            private _categoryUnlocks = +(_arsenal getOrDefault [_arsenalCategory, []]);
            _categoryUnlocks pushBackUnique _className;
            _arsenal set [_arsenalCategory, _categoryUnlocks];
            _categoriesToSync pushBackUnique _arsenalCategory;
        } forEach _items;

        {
            private _category = _x;
            private _categoryUnlocks = _arsenal getOrDefault [_category, []];
            _patch set [_category, _categoryUnlocks];
        } forEach _categoriesToSync;

        if (_commit) then {
            private _savedArsenal = _self call ["override", [_uid, _arsenal, false]];
            if !(_savedArsenal isEqualType createHashMap) exitWith {
                _result set ["message", "Virtual arsenal cache update returned invalid data."];
                _result
            };
            if (_savedArsenal isEqualTo createHashMap) exitWith {
                _result set ["message", "Failed to update virtual arsenal cache."];
                _result
            };
            _arsenal = _savedArsenal;
        };

        _result set ["success", true];
        _result set ["message", ""];
        _result set ["patch", _patch];
        _result set ["arsenal", _arsenal];
        _result
    }]
];

GVAR(VAStore) = createHashMapObject [GVAR(VABaseStore)];
GVAR(VAStore)