45a4f7460a
- add the imported server task addon to the current framework with task ownership, task catalog, mission-manager attack generation, org-owned reward routing, participant notifications, and reputation syncing - restructure org persistence so core org data, assets, fleet, and members are handled through the current Redis/extension model with matching Rust repository and service updates - wire the client CAD addon into the framework, actor device action, shared web UI bridge pattern, and task listing/acceptance flow - add a source-driven CAD web UI layout with ui.config.mjs and extend the shared web UI builder to support custom HTML template pages for multi-surface UIs
127 lines
5.1 KiB
Plaintext
127 lines
5.1 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* Author: IDSolutions
|
|
* Registers a defend task where players must hold a zone marked by a marker
|
|
*
|
|
* Arguments:
|
|
* 0: ID of the task <STRING>
|
|
* 1: Defense zone marker name <STRING>
|
|
* 2: Time to defend in seconds <NUMBER>
|
|
* 3: Amount of funds the company receives if the task is successful <NUMBER> (default: 0)
|
|
* 4: Amount of rating the company and player lose if the task is failed <NUMBER> (default: 0)
|
|
* 5: Amount of rating the company and player receive if the task is successful <NUMBER> (default: 0)
|
|
* 6: Should the mission end (MissionSuccess) if the task is successful <BOOL> (default: false)
|
|
* 7: Should the mission end (MissionFailed) if the task is failed <BOOL> (default: false)
|
|
* 8: Enemy wave count <NUMBER> (default: 3)
|
|
* 9: Time between waves in seconds <NUMBER> (default: 300)
|
|
* 10: Minimum BLUFOR units required in zone <NUMBER> (default: 1)
|
|
* 11: Equipment rewards <ARRAY> (default: [])
|
|
* 12: Supply rewards <ARRAY> (default: [])
|
|
* 13: Weapon rewards <ARRAY> (default: [])
|
|
* 14: Vehicle rewards <ARRAY> (default: [])
|
|
* 15: Special rewards <ARRAY> (default: [])
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* ["defend_zone_1", "defend_marker", 900, 500000, -100, 400, false, false, 3, 300, 1, ["ItemGPS"], ["FirstAidKit"], ["arifle_MX_F"], ["B_MRAP_01_F"], ["B_UAV_01_F"]] spawn forge_server_task_fnc_defend;
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
params [
|
|
["_taskID", "", [""]],
|
|
["_defenseZone", "", [""]],
|
|
["_defendTime", 600, [0]],
|
|
["_companyFunds", 0, [0]],
|
|
["_ratingFail", 0, [0]],
|
|
["_ratingSuccess", 0, [0]],
|
|
["_endSuccess", false, [false]],
|
|
["_endFail", false, [false]],
|
|
["_waveCount", 3, [0]],
|
|
["_waveCooldown", 300, [0]],
|
|
["_minBlufor", 1, [0]],
|
|
["_equipmentRewards", [], [[]]],
|
|
["_supplyRewards", [], [[]]],
|
|
["_weaponRewards", [], [[]]],
|
|
["_vehicleRewards", [], [[]]],
|
|
["_specialRewards", [], [[]]]
|
|
];
|
|
|
|
if (_defenseZone == "" || !(markerShape _defenseZone in ["RECTANGLE", "ELLIPSE"])) exitWith {
|
|
["ERROR", format ["Invalid defense zone marker: %1", _defenseZone]] call EFUNC(common,log);
|
|
};
|
|
|
|
private _result = 0;
|
|
private _startTime = time;
|
|
private _nextWaveTime = _startTime;
|
|
private _currentWave = 0;
|
|
private _zoneEmptyCounter = 0;
|
|
private _warningIssued = false;
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
GVAR(TaskStore) call ["trackParticipants", [_taskID, [], _defenseZone, 0]];
|
|
private _bluforInZone = count (allUnits select { _x isKindOf "CAManBase" && { side _x == west } && { alive _x }} inAreaArray _defenseZone);
|
|
private _timeElapsed = time - _startTime;
|
|
|
|
if (_bluforInZone < _minBlufor) then {
|
|
_zoneEmptyCounter = _zoneEmptyCounter + 1;
|
|
|
|
if (_zoneEmptyCounter == 15 && !_warningIssued) then {
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "warning", "Tasks", "Defense zone is empty. Return immediately."]];
|
|
_warningIssued = true;
|
|
};
|
|
} else {
|
|
_zoneEmptyCounter = 0;
|
|
_warningIssued = false;
|
|
};
|
|
|
|
if (_currentWave < _waveCount && time >= _nextWaveTime) then {
|
|
[_defenseZone, _taskID, _currentWave] call FUNC(spawnEnemyWave);
|
|
|
|
_currentWave = _currentWave + 1;
|
|
_nextWaveTime = time + _waveCooldown;
|
|
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "info", "Tasks", format ["Enemy forces approaching. Wave %1 of %2.", _currentWave, _waveCount]]];
|
|
};
|
|
|
|
if (_zoneEmptyCounter >= 30) then { _result = 1; };
|
|
|
|
(_result == 1) or ((_bluforInZone >= _minBlufor) && (_timeElapsed >= _defendTime) && (_currentWave >= _waveCount));
|
|
};
|
|
|
|
if (_result == 1) then {
|
|
[_taskID, "FAILED"] call BFUNC(taskSetState);
|
|
|
|
sleep 1;
|
|
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "warning", "Tasks", format ["Task failed: %1 reputation", _ratingFail]]];
|
|
GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingFail]];
|
|
GVAR(TaskStore) call ["clearTask", [_taskID]];
|
|
|
|
if (_endFail) then { ["MissionFail", false] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
|
|
} else {
|
|
private _rewards = createHashMap;
|
|
_rewards set ["funds", _companyFunds];
|
|
|
|
if (_equipmentRewards isNotEqualTo []) then { _rewards set ["equipment", _equipmentRewards]; };
|
|
if (_supplyRewards isNotEqualTo []) then { _rewards set ["supplies", _supplyRewards]; };
|
|
if (_weaponRewards isNotEqualTo []) then { _rewards set ["weapons", _weaponRewards]; };
|
|
if (_vehicleRewards isNotEqualTo []) then { _rewards set ["vehicles", _vehicleRewards]; };
|
|
if (_specialRewards isNotEqualTo []) then { _rewards set ["special", _specialRewards]; };
|
|
|
|
[_taskID, _rewards] call FUNC(handleTaskRewards);
|
|
[_taskID, "SUCCEEDED"] call BFUNC(taskSetState);
|
|
|
|
sleep 1;
|
|
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "success", "Tasks", format ["Task completed: %1 reputation, $%2 funds", _ratingSuccess, [_companyFunds] call EFUNC(common,formatNumber)]]];
|
|
GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingSuccess]];
|
|
GVAR(TaskStore) call ["clearTask", [_taskID]];
|
|
|
|
if (_endSuccess) then { ["MissionSuccess", true] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
|
|
};
|