Jacob Schmidt
ff7ff0c4e5
## Summary This finishes the org credit line workflow so it behaves like reserved treasury-backed credit instead of a simple member allowance. ## What changed - reserve org funds immediately when a credit line is assigned - track credit lines with: - approved amount - available amount - outstanding principal - interest rate - amount due - consume reserved credit during store checkout without charging org funds a second time - add credit line repayment through the bank app - sync richer credit line state into org and bank payloads/UI - keep legacy `amount` compatibility mapped to available credit for older consumers ## User-facing behavior - assigning a credit line now reduces available org funds immediately - spending on `credit_line` reduces available credit and creates debt with interest - the bank app now shows outstanding credit debt and allows repayment from personal bank funds - the org treasury view now shows reserved credit and outstanding due totals ## Validation - `cargo fmt` - `npm run build:webui` - `cargo test -p forge-services --quiet` - `cargo test -p forge-server --quiet` ## Follow-up checks - validate in-game that assigning a credit line reduces org funds immediately - validate store checkout with `credit_line` updates available credit and debt correctly - validate bank repayment decreases player bank balance, increases org funds, and reduces amount due Co-authored-by: Jacob Schmidt <innovativestudios@outlook.com> Reviewed-on: #2
129 lines
5.2 KiB
Plaintext
129 lines
5.2 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* Author: IDSolutions
|
|
* Registers an hvt task
|
|
*
|
|
* Arguments:
|
|
* 0: ID of the task <STRING>
|
|
* 1: Amount of HVTs KIA to fail the task <NUMBER>
|
|
* 2: Amount of HVTs Captured or KIA to complete the task <NUMBER>
|
|
* 3: Marker name for the extraction zone <STRING>
|
|
* 4: Amount of funds the company recieves if the task is successful <NUMBER> (default: 0)
|
|
* 5: Amount of rating the company and player lose if the task is failed <NUMBER> (default: 0)
|
|
* 6: Amount of rating the company and player recieve if the task is successful <NUMBER> (default: 0)
|
|
* 7: Subcategory of task <ARRAY> (default: [true, false])
|
|
* 8: Should the mission end (MissionSuccess) if the task is successful <BOOL> (default: false)
|
|
* 9: Should the mission end (MissionFailed) if the task is failed <BOOL> (default: false)
|
|
* 10: Amount of time before hvt(s) die <NUMBER> (default: -1)
|
|
* 11: Equipment rewards <ARRAY> (default: [])
|
|
* 12: Supply rewards <ARRAY> (default: [])
|
|
* 13: Weapon rewards <ARRAY> (default: [])
|
|
* 14: Vehicle rewards <ARRAY> (default: [])
|
|
* 15: Special rewards <ARRAY> (default: [])
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* ["task_name", 1, 1, "marker_name", 500000, -75, 300, [true, false], false, false] spawn forge_server_task_fnc_hvt;
|
|
* ["task_name", -1, 1, "", 500000, -75, 300, [false, true], false, false] spawn forge_server_task_fnc_hvt;
|
|
* ["task_name", 1, 1, "marker_name", 500000, -75, 300, [true, false], false, false, 45] spawn forge_server_task_fnc_hvt;
|
|
* ["task_name", -1, 1, "", 500000, -75, 300, [false, true], false, false, 45] spawn forge_server_task_fnc_hvt;
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
params [
|
|
["_taskID", "", [""]],
|
|
["_limitFail", -1, [0]],
|
|
["_limitSuccess", -1, [0]],
|
|
["_extZone", "", [""]],
|
|
["_companyFunds", 0, [0]],
|
|
["_ratingFail", 0, [0]],
|
|
["_ratingSuccess", 0, [0]],
|
|
["_type", [["_capture", true, [false]], ["_eliminate", false, [false]]]],
|
|
["_endSuccess", false, [false]],
|
|
["_endFail", false, [false]],
|
|
["_time", -1, [0]],
|
|
["_equipmentRewards", [], [[]]],
|
|
["_supplyRewards", [], [[]]],
|
|
["_weaponRewards", [], [[]]],
|
|
["_vehicleRewards", [], [[]]],
|
|
["_specialRewards", [], [[]]]
|
|
];
|
|
|
|
private _capture = (_this select 7) select 0;
|
|
private _eliminate = (_this select 7) select 1;
|
|
private _result = 0;
|
|
private _hvts = [];
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
_hvts = GVAR(TaskStore) call ["getTaskEntities", ["hvts", _taskID]];
|
|
GVAR(TaskStore) call ["trackParticipants", [_taskID, _hvts, _extZone, 250]];
|
|
count _hvts > 0
|
|
};
|
|
|
|
_hvts = GVAR(TaskStore) call ["getTaskEntities", ["hvts", _taskID]];
|
|
private _startTime = if (!isNil "_time") then { floor(time) } else { nil };
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
GVAR(TaskStore) call ["trackParticipants", [_taskID, _hvts, _extZone, 250]];
|
|
|
|
private _hvtsCaptive = ({ captive _x } count _hvts);
|
|
private _hvtsKilled = ({ !alive _x } count _hvts);
|
|
private _hvtsInZone = ({ _x inArea _extZone } count _hvts);
|
|
|
|
if (!isNil "_time") then {
|
|
private _timeExpired = (floor time - _startTime >= _time);
|
|
|
|
if (_capture && _hvtsKilled >= _limitFail) then { _result = 1; };
|
|
if (_capture && _hvtsCaptive < _limitSuccess && _timeExpired) then { _result = 1; };
|
|
if (_eliminate && _hvtsKilled < _limitSuccess && _timeExpired) then { _result = 1; };
|
|
|
|
(_result == 1) or (_capture && (_hvtsInZone >= _limitSuccess) && (_hvtsKilled < _limitFail)) or (_eliminate && (_hvtsKilled >= _limitSuccess))
|
|
} else {
|
|
if (_capture && (_hvtsKilled >= _limitFail)) then { _result = 1; };
|
|
|
|
(_result == 1) or (_capture && (_hvtsInZone >= _limitSuccess) && (_hvtsKilled < _limitFail)) or (_eliminate && (_hvtsKilled >= _limitSuccess))
|
|
};
|
|
};
|
|
|
|
if (_result == 1) then {
|
|
{ deleteVehicle _x } forEach _hvts;
|
|
|
|
[_taskID, "FAILED"] call BFUNC(taskSetState);
|
|
|
|
sleep 1;
|
|
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "warning", "Tasks", format ["Task failed: %1 reputation", _ratingFail]]];
|
|
GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingFail]];
|
|
GVAR(TaskStore) call ["clearTask", [_taskID]];
|
|
|
|
if (_endFail) then { ["MissionFail", false] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
|
|
} else {
|
|
{ deleteVehicle _x } forEach _hvts;
|
|
|
|
private _rewards = createHashMap;
|
|
_rewards set ["funds", _companyFunds];
|
|
|
|
if (_equipmentRewards isNotEqualTo []) then { _rewards set ["equipment", _equipmentRewards]; };
|
|
if (_supplyRewards isNotEqualTo []) then { _rewards set ["supplies", _supplyRewards]; };
|
|
if (_weaponRewards isNotEqualTo []) then { _rewards set ["weapons", _weaponRewards]; };
|
|
if (_vehicleRewards isNotEqualTo []) then { _rewards set ["vehicles", _vehicleRewards]; };
|
|
if (_specialRewards isNotEqualTo []) then { _rewards set ["special", _specialRewards]; };
|
|
|
|
[_taskID, _rewards] call FUNC(handleTaskRewards);
|
|
[_taskID, "SUCCEEDED"] call BFUNC(taskSetState);
|
|
|
|
sleep 1;
|
|
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "success", "Tasks", format ["Task completed: %1 reputation, $%2 funds", _ratingSuccess, [_companyFunds] call EFUNC(common,formatNumber)]]];
|
|
GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingSuccess]];
|
|
GVAR(TaskStore) call ["clearTask", [_taskID]];
|
|
|
|
if (_endSuccess) then { ["MissionSuccess", true] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
|
|
};
|