ebfe77a340
Implemented features: - High-performance Rust extension with Redis persistence - Actor/player management with loadout, position, and state tracking - Banking system with deposit, withdraw, and transfer operations - Physical and virtual garage/locker systems for vehicle and equipment storage - Organization management with member tracking and permissions - Client-side UI with React-like state management - Server-side event-driven architecture with CBA Events - Security: Self-transfer prevention at multiple layers - Logging system with per-module log files - ICOM module for inter-server communication Co-Authored-By: Warp <agent@warp.dev>
117 lines
3.7 KiB
Plaintext
117 lines
3.7 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* File: fnc_initVGarageClass.sqf
|
|
* Author: IDSolutions
|
|
* Date: 2025-12-16
|
|
* Last Update: 2025-12-19
|
|
* Public: No
|
|
*
|
|
* Description:
|
|
* Initializes the Virtual Garage class for managing player garage unlocks.
|
|
* Provides methods for syncing, saving, and applying virtual items to BIS Garage.
|
|
*
|
|
* Parameter(s):
|
|
* None
|
|
*
|
|
* Returns:
|
|
* vGarage class object [HASHMAP OBJECT]
|
|
*
|
|
* Example(s):
|
|
* [] call forge_client_locker_fnc_initVGClass;
|
|
*/
|
|
|
|
#pragma hemtt ignore_variables ["_self"]
|
|
GVAR(VGarageClass) = createHashMapObject [[
|
|
["#type", "IVGarageClass"],
|
|
["#create", {
|
|
_self set ["uid", (getPlayerUID player)];
|
|
_self set ["vGarage", createHashMap];
|
|
_self set ["isLoaded", false];
|
|
_self set ["lastSave", time];
|
|
|
|
private _vGarage = createHashMap;
|
|
_vGarage set ["cars", ["B_Quadbike_01_F"]];
|
|
_vGarage set ["armor", []];
|
|
_vGarage set ["helis", []];
|
|
_vGarage set ["planes", []];
|
|
_vGarage set ["naval", []];
|
|
_vGarage set ["other", []];
|
|
|
|
_self set ["vGarage", _vGarage];
|
|
}],
|
|
["init", {
|
|
private _uid = _self get "uid";
|
|
private _vGarage = _self get "vGarage";
|
|
|
|
[SRPC(garage,requestInitVG), [_uid, _vGarage]] call CFUNC(serverEvent);
|
|
|
|
systemChat format ["VGarage loaded for %1", (name player)];
|
|
diag_log "[FORGE:Client:VGarage] VGarage Class Initialized!";
|
|
}],
|
|
["save", {
|
|
params [["_sync", false, [false]]];
|
|
|
|
private _uid = _self get "uid";
|
|
[SRPC(garage,requestSaveVG), [_uid, _sync]] call CFUNC(serverEvent);
|
|
|
|
_self set ["lastSave", time];
|
|
}],
|
|
["sync", {
|
|
params [["_data", createHashMap, [createHashMap]], ["_jip", false, [false]]];
|
|
|
|
private _vGarage = _self get "vGarage";
|
|
private _isLoaded = _self get "isLoaded";
|
|
|
|
if (_data isEqualTo createHashMap) exitWith { diag_log "[FORGE:Client:VGarage] Empty data received for sync, skipping."; };
|
|
|
|
{
|
|
_vGarage set [_x, _y];
|
|
|
|
if (_jip) then {
|
|
switch (_x) do {
|
|
case "cars": { _self call ["apply", ["cars"]]; };
|
|
case "armor": { _self call ["apply", ["armor"]]; };
|
|
case "helis": { _self call ["apply", ["helis"]]; };
|
|
case "planes": { _self call ["apply", ["planes"]]; };
|
|
case "naval": { _self call ["apply", ["naval"]]; };
|
|
case "other": { _self call ["apply", ["other"]]; };
|
|
default {};
|
|
};
|
|
};
|
|
} forEach _data;
|
|
|
|
_self set ["vGarage", _vGarage];
|
|
|
|
if !(_isLoaded) then { _self set ["isLoaded", true]; };
|
|
diag_log "[FORGE:Client:VGarage] Sync completed";
|
|
}],
|
|
["get", {
|
|
params [["_key", "", [""]], ["_default", nil, [[], "", 0, false, createHashMap]]];
|
|
|
|
private _vGarage = _self get "vGarage";
|
|
_vGarage getOrDefault [_key, _default];
|
|
}],
|
|
["apply", {
|
|
params [["_key", "", [""]]];
|
|
|
|
private _vehicles = _self call ["get", [_key, []]];
|
|
private _array = switch (_key) do {
|
|
case "cars": { GVAR(Cars) };
|
|
case "armor": { GVAR(Armor) };
|
|
case "helis": { GVAR(Helis) };
|
|
case "planes": { GVAR(Planes) };
|
|
case "naval": { GVAR(Naval) };
|
|
case "other": { GVAR(Other) };
|
|
default { [] };
|
|
};
|
|
|
|
{
|
|
_array append [getText (configFile >> "CfgVehicles" >> _x >> "model"), [configFile >> "CfgVehicles" >> _x]];
|
|
} forEach _vehicles;
|
|
}]
|
|
]];
|
|
|
|
SETVAR(player,FORGE_VGarageClass,GVAR(VGarageClass));
|
|
GVAR(VGarageClass)
|