bdc1e36e63
- replace placeholder garage interaction with real UI open flow - add catalog/session/UI bridge services for hydrate, sync, store, and retrieve actions - migrate garage web UI bundle to new app shell/runtime structure - align org/store function naming with shared init and UI bridge patterns
73 lines
2.1 KiB
Plaintext
73 lines
2.1 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* File: fnc_initClass.sqf
|
|
* Author: IDSolutions
|
|
* Date: 2025-12-17
|
|
* Last Update: 2026-02-13
|
|
* Public: No
|
|
*
|
|
* Description:
|
|
* Initializes the Garage class for managing player vehicles.
|
|
* Provides methods for syncing, saving, and applying vehicles to the player's garage.
|
|
*
|
|
* Arguments:
|
|
* None
|
|
*
|
|
* Return Value:
|
|
* Garage class object [HASHMAP OBJECT]
|
|
*
|
|
* Example:
|
|
* call forge_client_garage_fnc_initClass
|
|
*/
|
|
|
|
#pragma hemtt ignore_variables ["_self"]
|
|
GVAR(GarageBaseClass) = compileFinal createHashMapFromArray [
|
|
["#type", "GarageBaseClass"],
|
|
["#create", compileFinal {
|
|
_self set ["uid", (getPlayerUID player)];
|
|
_self set ["garage", createHashMap];
|
|
_self set ["isLoaded", false];
|
|
_self set ["lastSave", time];
|
|
}],
|
|
["init", compileFinal {
|
|
private _uid = _self get "uid";
|
|
private _garage = _self get "garage";
|
|
|
|
[SRPC(garage,requestInitGarage), [_uid, _garage]] call CFUNC(serverEvent);
|
|
|
|
systemChat format ["Garage loaded for %1", (name player)];
|
|
diag_log "[FORGE:Client:Garage] Garage Class Initialized!";
|
|
}],
|
|
["save", compileFinal {
|
|
private _uid = _self get "uid";
|
|
[SRPC(garage,requestSaveGarage), [_uid]] call CFUNC(serverEvent);
|
|
|
|
_self set ["lastSave", time];
|
|
}],
|
|
["sync", compileFinal {
|
|
params [["_data", createHashMap, [createHashMap]]];
|
|
|
|
private _isLoaded = _self get "isLoaded";
|
|
private _garage = createHashMap;
|
|
|
|
{ _garage set [_x, _y]; } forEach _data;
|
|
_self set ["garage", _garage];
|
|
|
|
if !(_isLoaded) then { _self set ["isLoaded", true]; };
|
|
diag_log "[FORGE:Client:Garage] Sync completed";
|
|
}],
|
|
["getGarageState", compileFinal {
|
|
_self getOrDefault ["garage", createHashMap]
|
|
}],
|
|
["get", compileFinal {
|
|
params [["_key", "", [""]], ["_default", nil, [[], "", 0, false, createHashMap]]];
|
|
|
|
private _garage = _self get "garage";
|
|
_garage getOrDefault [_key, _default];
|
|
}]
|
|
];
|
|
|
|
GVAR(GarageClass) = createHashMapObject [GVAR(GarageBaseClass)];
|
|
GVAR(GarageClass)
|