45a4f7460a
- add the imported server task addon to the current framework with task ownership, task catalog, mission-manager attack generation, org-owned reward routing, participant notifications, and reputation syncing - restructure org persistence so core org data, assets, fleet, and members are handled through the current Redis/extension model with matching Rust repository and service updates - wire the client CAD addon into the framework, actor device action, shared web UI bridge pattern, and task listing/acceptance flow - add a source-driven CAD web UI layout with ui.config.mjs and extend the shared web UI builder to support custom HTML template pages for multi-surface UIs
121 lines
4.6 KiB
Plaintext
121 lines
4.6 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* Author: IDSolutions
|
|
* Registers a delivery task
|
|
*
|
|
* Arguments:
|
|
* 0: ID of the task <STRING>
|
|
* 1: Amount of damaged cargo to fail the task <NUMBER>
|
|
* 2: Amount of cargo delivered to complete the task <NUMBER>
|
|
* 3: Marker name for the delivery zone <STRING>
|
|
* 4: Amount of funds the company receives if the task is successful <NUMBER> (default: 0)
|
|
* 5: Amount of rating the company and player lose if the task is failed <NUMBER> (default: 0)
|
|
* 6: Amount of rating the company and player receive if the task is successful <NUMBER> (default: 0)
|
|
* 7: Should the mission end (MissionSuccess) if the task is successful <BOOL> (default: false)
|
|
* 8: Should the mission end (MissionFailed) if the task is failed <BOOL> (default: false)
|
|
* 9: Amount of time to complete delivery <NUMBER> (default: -1)
|
|
* 10: Equipment rewards <ARRAY> (default: [])
|
|
* 11: Supply rewards <ARRAY> (default: [])
|
|
* 12: Weapon rewards <ARRAY> (default: [])
|
|
* 13: Vehicle rewards <ARRAY> (default: [])
|
|
* 14: Special rewards <ARRAY> (default: [])
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* ["delivery_1", 1, 3, "delivery_zone", 250000, -75, 300, false, false] spawn forge_server_task_fnc_delivery;
|
|
* ["delivery_1", 1, 3, "delivery_zone", 250000, -75, 300, false, false, 900] spawn forge_server_task_fnc_delivery;
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
params [
|
|
["_taskID", "", [""]],
|
|
["_limitFail", -1, [0]],
|
|
["_limitSuccess", -1, [0]],
|
|
["_deliveryZone", "", [""]],
|
|
["_companyFunds", 0, [0]],
|
|
["_ratingFail", 0, [0]],
|
|
["_ratingSuccess", 0, [0]],
|
|
["_endSuccess", false, [false]],
|
|
["_endFail", false, [false]],
|
|
["_time", -1, [0]],
|
|
["_equipmentRewards", [], [[]]],
|
|
["_supplyRewards", [], [[]]],
|
|
["_weaponRewards", [], [[]]],
|
|
["_vehicleRewards", [], [[]]],
|
|
["_specialRewards", [], [[]]]
|
|
];
|
|
|
|
private _result = 0;
|
|
private _cargo = [];
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
_cargo = GVAR(TaskStore) call ["getTaskEntities", ["cargo", _taskID]];
|
|
GVAR(TaskStore) call ["trackParticipants", [_taskID, _cargo, _deliveryZone, 125]];
|
|
count _cargo > 0
|
|
};
|
|
|
|
_cargo = GVAR(TaskStore) call ["getTaskEntities", ["cargo", _taskID]];
|
|
private _startTime = if (_time isNotEqualTo -1) then { floor(time) } else { nil };
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
GVAR(TaskStore) call ["trackParticipants", [_taskID, _cargo, _deliveryZone, 125]];
|
|
|
|
private _cargoDelivered = ({ _x inArea _deliveryZone && (damage _x) < 0.7 } count _cargo);
|
|
private _cargoDamaged = ({ damage _x >= 0.7 } count _cargo);
|
|
|
|
if (_time isNotEqualTo -1) then {
|
|
private _timeExpired = (floor time - _startTime >= _time);
|
|
|
|
if (_cargoDamaged >= _limitFail) then { _result = 1; };
|
|
if (_cargoDelivered < _limitSuccess && _timeExpired) then { _result = 1; };
|
|
|
|
(_result == 1) or ((_cargoDelivered >= _limitSuccess) && (_cargoDamaged < _limitFail))
|
|
} else {
|
|
if (_cargoDamaged >= _limitFail) then { _result = 1; };
|
|
|
|
(_result == 1) or ((_cargoDelivered >= _limitSuccess) && (_cargoDamaged < _limitFail))
|
|
};
|
|
};
|
|
|
|
if (_result == 1) then {
|
|
{ deleteVehicle _x } forEach _cargo;
|
|
|
|
[_taskID, "FAILED"] call BFUNC(taskSetState);
|
|
|
|
sleep 1;
|
|
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "warning", "Tasks", format ["Task failed: %1 reputation", _ratingFail]]];
|
|
GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingFail]];
|
|
GVAR(TaskStore) call ["clearTask", [_taskID]];
|
|
|
|
if (_endFail) then { ["MissionFail", false] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
|
|
} else {
|
|
{ deleteVehicle _x } forEach _cargo;
|
|
|
|
private _rewards = createHashMap;
|
|
_rewards set ["funds", _companyFunds];
|
|
|
|
if (_equipmentRewards isNotEqualTo []) then { _rewards set ["equipment", _equipmentRewards]; };
|
|
if (_supplyRewards isNotEqualTo []) then { _rewards set ["supplies", _supplyRewards]; };
|
|
if (_weaponRewards isNotEqualTo []) then { _rewards set ["weapons", _weaponRewards]; };
|
|
if (_vehicleRewards isNotEqualTo []) then { _rewards set ["vehicles", _vehicleRewards]; };
|
|
if (_specialRewards isNotEqualTo []) then { _rewards set ["special", _specialRewards]; };
|
|
|
|
[_taskID, _rewards] call FUNC(handleTaskRewards);
|
|
[_taskID, "SUCCEEDED"] call BFUNC(taskSetState);
|
|
|
|
sleep 1;
|
|
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "success", "Tasks", format ["Task completed: %1 reputation, $%2 funds", _ratingSuccess, [_companyFunds] call EFUNC(common,formatNumber)]]];
|
|
GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingSuccess]];
|
|
GVAR(TaskStore) call ["clearTask", [_taskID]];
|
|
|
|
if (_endSuccess) then { ["MissionSuccess", true] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
|
|
};
|