Jacob Schmidt
ff7ff0c4e5
## Summary This finishes the org credit line workflow so it behaves like reserved treasury-backed credit instead of a simple member allowance. ## What changed - reserve org funds immediately when a credit line is assigned - track credit lines with: - approved amount - available amount - outstanding principal - interest rate - amount due - consume reserved credit during store checkout without charging org funds a second time - add credit line repayment through the bank app - sync richer credit line state into org and bank payloads/UI - keep legacy `amount` compatibility mapped to available credit for older consumers ## User-facing behavior - assigning a credit line now reduces available org funds immediately - spending on `credit_line` reduces available credit and creates debt with interest - the bank app now shows outstanding credit debt and allows repayment from personal bank funds - the org treasury view now shows reserved credit and outstanding due totals ## Validation - `cargo fmt` - `npm run build:webui` - `cargo test -p forge-services --quiet` - `cargo test -p forge-server --quiet` ## Follow-up checks - validate in-game that assigning a credit line reduces org funds immediately - validate store checkout with `credit_line` updates available credit and debt correctly - validate bank repayment decreases player bank balance, increases org funds, and reduces amount due Co-authored-by: Jacob Schmidt <innovativestudios@outlook.com> Reviewed-on: #2
115 lines
4.0 KiB
Plaintext
115 lines
4.0 KiB
Plaintext
#include "..\script_component.hpp"
|
|
|
|
/*
|
|
* Author: IDSolutions
|
|
* Registers a defuse task
|
|
*
|
|
* Arguments:
|
|
* 0: ID of the task <STRING>
|
|
* 1: Amount of entities destroyed to fail the task <NUMBER>
|
|
* 2: Amount of ieds defused to complete the task <NUMBER>
|
|
* 3: Amount of funds the company recieves if the task is successful <NUMBER> (default: 0)
|
|
* 4: Amount of rating the company and player lose if the task is failed <NUMBER> (default: 0)
|
|
* 5: Amount of rating the company and player recieve if the task is successful <NUMBER> (default: 0)
|
|
* 6: Should the mission end (MissionSuccess) if the task is successful <BOOL> (default: false)
|
|
* 7: Should the mission end (MissionFailed) if the task is failed <BOOL> (default: false)
|
|
* 8: Equipment rewards <ARRAY> (default: [])
|
|
* 9: Supply rewards <ARRAY> (default: [])
|
|
* 10: Weapon rewards <ARRAY> (default: [])
|
|
* 11: Vehicle rewards <ARRAY> (default: [])
|
|
* 12: Special rewards <ARRAY> (default: [])
|
|
*
|
|
* Return Value:
|
|
* None
|
|
*
|
|
* Example:
|
|
* ["task_name", 2, 3, 375000, -75, 300, false, false] spawn forge_server_task_fnc_defuse;
|
|
*
|
|
* Public: Yes
|
|
*/
|
|
|
|
params [
|
|
["_taskID", "", [""]],
|
|
["_limitFail", -1, [0]],
|
|
["_limitSuccess", -1, [0]],
|
|
["_companyFunds", 0, [0]],
|
|
["_ratingFail", 0, [0]],
|
|
["_ratingSuccess", 0, [0]],
|
|
["_endSuccess", false, [false]],
|
|
["_endFail", false, [false]],
|
|
["_equipmentRewards", [], [[]]],
|
|
["_supplyRewards", [], [[]]],
|
|
["_weaponRewards", [], [[]]],
|
|
["_vehicleRewards", [], [[]]],
|
|
["_specialRewards", [], [[]]]
|
|
];
|
|
|
|
private _result = 0;
|
|
private _ieds = [];
|
|
private _entities = [];
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
_ieds = GVAR(TaskStore) call ["getTaskEntities", ["ieds", _taskID]];
|
|
count _ieds > 0
|
|
};
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
_entities = GVAR(TaskStore) call ["getTaskEntities", ["entities", _taskID]];
|
|
GVAR(TaskStore) call ["trackParticipants", [_taskID, _ieds + _entities, "", 250]];
|
|
count _entities > 0
|
|
};
|
|
|
|
_ieds = GVAR(TaskStore) call ["getTaskEntities", ["ieds", _taskID]];
|
|
_entities = GVAR(TaskStore) call ["getTaskEntities", ["entities", _taskID]];
|
|
|
|
waitUntil {
|
|
sleep 1;
|
|
GVAR(TaskStore) call ["trackParticipants", [_taskID, _ieds + _entities, "", 250]];
|
|
|
|
private _entitiesDestroyed = ({ !alive _x } count _entities);
|
|
|
|
if (_entitiesDestroyed >= _limitFail) then { _result = 1; };
|
|
|
|
(_result == 1) or ((GVAR(TaskStore) call ["getDefuseCount", [_taskID]]) >= _limitSuccess && (_entitiesDestroyed < _limitFail))
|
|
};
|
|
|
|
if (_result == 1) then {
|
|
{ deleteVehicle _x } forEach _ieds;
|
|
{ deleteVehicle _x } forEach _entities;
|
|
|
|
[_taskID, "FAILED"] call BFUNC(taskSetState);
|
|
|
|
sleep 1;
|
|
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "warning", "Tasks", format ["Task failed: %1 reputation", _ratingFail]]];
|
|
GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingFail]];
|
|
|
|
if (_endFail) then { ["MissionFail", false] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
|
|
} else {
|
|
{ deleteVehicle _x } forEach _ieds;
|
|
{ deleteVehicle _x } forEach _entities;
|
|
|
|
private _rewards = createHashMap;
|
|
_rewards set ["funds", _companyFunds];
|
|
|
|
if (_equipmentRewards isNotEqualTo []) then { _rewards set ["equipment", _equipmentRewards]; };
|
|
if (_supplyRewards isNotEqualTo []) then { _rewards set ["supplies", _supplyRewards]; };
|
|
if (_weaponRewards isNotEqualTo []) then { _rewards set ["weapons", _weaponRewards]; };
|
|
if (_vehicleRewards isNotEqualTo []) then { _rewards set ["vehicles", _vehicleRewards]; };
|
|
if (_specialRewards isNotEqualTo []) then { _rewards set ["special", _specialRewards]; };
|
|
|
|
[_taskID, _rewards] call FUNC(handleTaskRewards);
|
|
[_taskID, "SUCCEEDED"] call BFUNC(taskSetState);
|
|
|
|
sleep 1;
|
|
|
|
GVAR(TaskStore) call ["notifyParticipants", [_taskID, "success", "Tasks", format ["Task completed: %1 reputation, $%2 funds", _ratingSuccess, [_companyFunds] call EFUNC(common,formatNumber)]]];
|
|
GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingSuccess]];
|
|
|
|
if (_endSuccess) then { ["MissionSuccess", true] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
|
|
};
|
|
|
|
GVAR(TaskStore) call ["clearTask", [_taskID]];
|