forge/arma/server/addons/task/functions/fnc_attack.sqf

#include "..\script_component.hpp"

/*
 * Author: IDSolutions
 * Registers an attack task
 *
 * Arguments:
 * 0: ID of the task <STRING>
 * 1: Amount of targets escaped to fail the task <NUMBER>
 * 2: Amount of targets eliminated to complete the task <NUMBER>
 * 3: Amount of funds the company recieves if the task is successful <NUMBER> (default: 0)
 * 4: Amount of rating the company and player lose if the task is failed <NUMBER> (default: 0)
 * 5: Amount of rating the company and player recieve if the task is successful <NUMBER> (default: 0)
 * 6: Should the mission end (MissionSuccess) if the task is successful <BOOL> (default: false)
 * 7: Should the mission end (MissionFailed) if the task is failed <BOOL> (default: false)
 * 8: Amount of time before target(s) escape <NUMBER> (default: 0, 0 = no limit)
 * 9: Equipment rewards <ARRAY> (default: [])
 * 10: Supply rewards <ARRAY> (default: [])
 * 11: Weapon rewards <ARRAY> (default: [])
 * 12: Vehicle rewards <ARRAY> (default: [])
 * 13: Special rewards <ARRAY> (default: [])
 *
 * Return Value:
 * None
 *
 * Example:
 * ["task_name", 1, 2, 1500000, -75, 375, false, false] spawn forge_server_task_fnc_attack;
 * ["task_name", 1, 2, 1500000, -75, 375, false, false, 45] spawn forge_server_task_fnc_attack;
 *
 * Public: Yes
 */

params [
	["_taskID", "", [""]],
	["_limitFail", -1, [0]],
	["_limitSuccess", -1, [0]],
	["_companyFunds", 0, [0]],
	["_ratingFail", 0, [0]],
	["_ratingSuccess", 0, [0]],
	["_endSuccess", false, [false]],
	["_endFail", false, [false]],
	["_timeLimit", 0, [0]],
	["_equipmentRewards", [], [[]]],
	["_supplyRewards", [], [[]]],
	["_weaponRewards", [], [[]]],
	["_vehicleRewards", [], [[]]],
	["_specialRewards", [], [[]]]
];

private _result = 0;
private _targets = [];

waitUntil {
	sleep 1;
	_targets = GVAR(TaskStore) call ["getTaskEntities", ["targets", _taskID]];
    GVAR(TaskStore) call ["trackParticipants", [_taskID, _targets, "", 300]];
	count _targets > 0
};

_targets = GVAR(TaskStore) call ["getTaskEntities", ["targets", _taskID]];

if (_timeLimit isNotEqualTo 0) then {
    private _catalogEntry = GVAR(TaskStore) call ["getTaskCatalogEntry", [_taskID]];
    ["INFO", format [
        "Attack task %1 initial state before acceptance wait. Accepted=%2, RequesterUid='%3', Source='%4', TimeLimit=%5s",
        _taskID,
        _catalogEntry getOrDefault ["accepted", false],
        _catalogEntry getOrDefault ["requesterUid", ""],
        _catalogEntry getOrDefault ["source", ""],
        _timeLimit
    ]] call EFUNC(common,log);

    ["INFO", format ["Attack task %1 waiting for acceptance before starting %2s time limit.", _taskID, _timeLimit]] call EFUNC(common,log);
    waitUntil {
        sleep 1;
        GVAR(TaskStore) call ["isTaskAccepted", [_taskID]]
    };

    ["INFO", format ["Attack task %1 accepted. Starting %2s time limit.", _taskID, _timeLimit]] call EFUNC(common,log);
};

private _startTime = if (_timeLimit isNotEqualTo 0) then { floor(time) } else { nil };

waitUntil {
	sleep 1;
    GVAR(TaskStore) call ["trackParticipants", [_taskID, _targets, "", 300]];

	private _targetsKilled = ({ !alive _x } count _targets);

	if (_timeLimit isNotEqualTo 0) then {
		private _timeExpired = (floor time - _startTime >= _timeLimit);

		if (_targetsKilled < _limitSuccess && _timeExpired) then {
            ["WARNING", format [
                "Attack task %1 failed by timeout. TargetsKilled=%2, Required=%3, TimeLimit=%4s",
                _taskID,
                _targetsKilled,
                _limitSuccess,
                _timeLimit
            ]] call EFUNC(common,log);
            _result = 1;
        };

		(_result == 1) or (_targetsKilled >= _limitSuccess)
	} else {
		(_targetsKilled >= _limitSuccess)
	};
};

if (_result == 1) then {
	{ deleteVehicle _x } forEach _targets;

	[_taskID, "FAILED"] call BFUNC(taskSetState);
    GVAR(TaskStore) call ["setTaskStatus", [_taskID, "failed"]];

    sleep 1;

    GVAR(TaskStore) call ["notifyParticipants", [_taskID, "warning", "Tasks", format ["Task failed: %1 reputation", _ratingFail]]];
    GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingFail]];
    GVAR(TaskStore) call ["clearTask", [_taskID]];

    if (_endFail) then { ["MissionFail", false] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
} else {
    ["INFO", format [
        "Attack task %1 succeeded. TargetsRequired=%2, TargetsKilled=%3",
        _taskID,
        _limitSuccess,
        { !alive _x } count _targets
    ]] call EFUNC(common,log);

	{ deleteVehicle _x } forEach _targets;

	private _rewards = createHashMap;
    _rewards set ["funds", _companyFunds];

    if (_equipmentRewards isNotEqualTo []) then { _rewards set ["equipment", _equipmentRewards]; };
    if (_supplyRewards isNotEqualTo []) then { _rewards set ["supplies", _supplyRewards]; };
    if (_weaponRewards isNotEqualTo []) then { _rewards set ["weapons", _weaponRewards]; };
    if (_vehicleRewards isNotEqualTo []) then { _rewards set ["vehicles", _vehicleRewards]; };
    if (_specialRewards isNotEqualTo []) then { _rewards set ["special", _specialRewards]; };

    [_taskID, _rewards] call FUNC(handleTaskRewards);
    [_taskID, "SUCCEEDED"] call BFUNC(taskSetState);
    GVAR(TaskStore) call ["setTaskStatus", [_taskID, "succeeded"]];

    sleep 1;

    GVAR(TaskStore) call ["notifyParticipants", [_taskID, "success", "Tasks", format ["Task completed: %1 reputation, $%2 funds", _ratingSuccess, [_companyFunds] call EFUNC(common,formatNumber)]]];
    GVAR(TaskStore) call ["applyRatingOutcome", [_taskID, _ratingSuccess]];
    GVAR(TaskStore) call ["clearTask", [_taskID]];

    if (_endSuccess) then { ["MissionSuccess", true] remoteExecCall ["BIS_fnc_endMission", playerSide]; };
};