forge/arma/server/addons/garage/functions/fnc_initGarageStore.sqf

#include "..\script_component.hpp"

/*
 * File: fnc_initGarageStore.sqf
 * Author: IDSolutions
 * Date: 2025-12-17
 * Last Update: 2026-04-01
 * Public: No
 *
 * Description:
 * Initializes the Garage store for managing player vehicles.
 * Garage hot state is owned by the extension; SQF acts as a thin bridge.
 *
 * Arguments:
 * None
 *
 * Return Value:
 * Garage store object [HASHMAP OBJECT]
 *
 * Example:
 * call forge_server_garage_fnc_initGarageStore
 */

#pragma hemtt ignore_variables ["_self"]
GVAR(GarageBaseStore) = compileFinal createHashMapFromArray [
    ["#base", EGVAR(common,BaseStore)],
    ["#type", "GarageBaseStore"],
    ["#create", compileFinal {
        ["INFO", "Garage Store Initialized!"] call EFUNC(common,log);
    }],
    ["callHotGarage", compileFinal {
        params [["_function", "", [""]], ["_arguments", [], [[]]]];

        if (_function isEqualTo "") exitWith { createHashMap };

        [_function, _arguments] call EFUNC(extension,extCall) params ["_result", "_isSuccess"];
        if !(_isSuccess) exitWith { createHashMap };
        if !(_result isEqualType "") exitWith { createHashMap };
        if ((_result find "Error:") == 0) exitWith {
            ["ERROR", format ["Garage extension call '%1' failed: %2", _function, _result]] call EFUNC(common,log);
            createHashMap
        };

        private _data = fromJSON _result;
        if !(_data isEqualType createHashMap) exitWith { createHashMap };
        _data
    }],
    ["loadHotGarage", compileFinal {
        params [["_uid", "", [""]], ["_initialize", false, [false]]];

        if (_uid isEqualTo "") exitWith { createHashMap };

        private _command = ["garage:hot:get", "garage:hot:init"] select _initialize;
        _self call ["callHotGarage", [_command, [_uid]]]
    }],
    ["init", compileFinal {
        params [["_uid", "", [""]]];

        private _player = [_uid] call EFUNC(common,getPlayer);
        if (isNull _player) exitWith { createHashMap };

        private _garage = _self call ["loadHotGarage", [_uid, true]];
        if (_garage isEqualTo createHashMap) then {
            ["ERROR", format ["Failed to initialize garage for %1! Using fallback garage.", _uid]] call EFUNC(common,log);
        };

        [CRPC(garage,responseInitGarage), [_garage], _player] call CFUNC(targetEvent);
        _garage
    }],
    ["get", compileFinal {
        params [["_uid", "", [""]], ["_field", "", [""]]];

        private _garage = _self call ["loadHotGarage", [_uid, false]];
        if (_garage isEqualTo createHashMap) then {
            _garage = _self call ["loadHotGarage", [_uid, true]];
        };

        if (_field isEqualTo "") exitWith { _garage };
        _garage getOrDefault [_field, createHashMap]
    }],
    ["override", compileFinal {
        params [
            ["_uid", "", [""]],
            ["_data", createHashMap, [createHashMap]],
            ["_save", false, [false]]
        ];

        if (_uid isEqualTo "") exitWith { createHashMap };
        if !(_data isEqualType createHashMap) exitWith { createHashMap };

        private _garage = _self call ["callHotGarage", ["garage:hot:override", [_uid, toJSON _data]]];
        if (_save && { _garage isNotEqualTo createHashMap }) then {
            private _savedGarage = _self call ["callHotGarage", ["garage:hot:save", [_uid]]];
            if (_savedGarage isNotEqualTo createHashMap) then {
                _garage = _savedGarage;
            } else {
                _garage = createHashMap;
            };
        };

        _garage
    }],
    ["set", compileFinal {
        params [
            ["_uid", "", [""]],
            ["_field", "", [""]],
            ["_value", nil, [0, "", [], false, createHashMap, objNull, grpNull]],
            ["_sync", false, [false]]
        ];

        if (_uid isEqualTo "" || { _field isEqualTo "" }) exitWith { createHashMap };

        private _garage = _self call ["get", [_uid, ""]];
        if !(_garage isEqualType createHashMap) exitWith { createHashMap };

        _garage set [_field, _value];
        private _updatedGarage = _self call ["override", [_uid, _garage, _sync]];
        if !(_updatedGarage isEqualType createHashMap) exitWith { createHashMap };
        if (_updatedGarage isEqualTo createHashMap) exitWith { createHashMap };

        createHashMapFromArray [[_field, _updatedGarage getOrDefault [_field, _value]]]
    }],
    ["mset", compileFinal {
        params [
            ["_uid", "", [""]],
            ["_fieldValuePairs", createHashMap, [createHashMap]],
            ["_sync", false, [false]]
        ];

        if (_uid isEqualTo "") exitWith { createHashMap };
        if !(_fieldValuePairs isEqualType createHashMap) exitWith { createHashMap };

        private _garage = _self call ["get", [_uid, ""]];
        if !(_garage isEqualType createHashMap) exitWith { createHashMap };

        { _garage set [_x, _y]; } forEach _fieldValuePairs;
        private _updatedGarage = _self call ["override", [_uid, _garage, _sync]];
        if !(_updatedGarage isEqualType createHashMap) exitWith { createHashMap };
        if (_updatedGarage isEqualTo createHashMap) exitWith { createHashMap };

        +_fieldValuePairs
    }],
    ["save", compileFinal {
        params [["_uid", "", [""]]];

        if (_uid isEqualTo "") exitWith { createHashMap };
        _self call ["callHotGarage", ["garage:hot:save", [_uid]]]
    }],
    ["remove", compileFinal {
        params [["_uid", "", [""]]];

        if (_uid isEqualTo "") exitWith { false };

        ["garage:hot:remove", [_uid]] call EFUNC(extension,extCall) params ["_result", "_isSuccess"];
        _isSuccess && { _result isEqualTo "OK" }
    }],
    ["storeVehicle", compileFinal {
        params [
            ["_uid", "", [""]],
            ["_payloadJson", "", [""]]
        ];

        if (_uid isEqualTo "" || { _payloadJson isEqualTo "" }) exitWith { createHashMap };
        _self call ["callHotGarage", ["garage:hot:add", [_uid, _payloadJson]]]
    }],
    ["retrieveVehicle", compileFinal {
        params [
            ["_uid", "", [""]],
            ["_payloadJson", "", [""]]
        ];

        if (_uid isEqualTo "" || { _payloadJson isEqualTo "" }) exitWith { createHashMap };
        _self call ["callHotGarage", ["garage:hot:remove_vehicle", [_uid, _payloadJson]]]
    }]
];

GVAR(GarageStore) = createHashMapObject [GVAR(GarageBaseStore)];
GVAR(GarageStore)