#include "..\script_component.hpp"

/*
 * Function: forge_server_db_fnc_saveToTemp
 * Author: J. Schmidt
 * 
 * Description:
 * Saves data to temporary mission store (not persisted between sessions)
 *
 * Arguments:
 * 0: _name - Store name <STRING>
 * 1: _key - Key to save under <STRING>
 * 2: _keyField - Field of the key to update <STRING>
 * 3: _data - Data to save <STRING, ARRAY, NUMBER, BOOLEAN, HASHMAP>
 *
 * Return Value:
 * Success <BOOL>
 */

params [["_name", "", [""]], ["_key", "", [""]], ["_keyField", "", [""]], ["_data", nil, ["", [], 0, true, createHashMap]]];

if (_name isEqualTo "" || _key isEqualTo "" || isNil "_data") exitWith { ERROR_MSG("Store name, key and, or data cannot be empty"); false };

private _store = missionNamespace getVariable [_name, createHashMap];

if (_keyField isEqualTo "") then {
    _store set [_key, _data];
} else {
    private _keyData = _store get _key;

    _keyData set [_keyField, _data];
    _store set [_key, _keyData];
};

missionNamespace setVariable [_name, _store];

true