#include "..\script_component.hpp"

_data = _this;

if (_data isEqualTo [""]) then {
    companyShareholders = (configFile >> "CfgPatches" >> "forge_server_main" >> "companyShareholders") call BFUNC(getCfgData);
    publicVariable "companyShareholders";

    companyFunds = "OP_BUDGET" call BFUNC(getParamValue);
    publicVariable "companyFunds";

    companyRating = "OP_RATING" call BFUNC(getParamValue);
    publicVariable "companyRating";

    diag_log "No Server Entry Found!";
    ["save"] call FUNC(handleServerState);

    value_serverDone = true;
    publicVariable "value_serverDone";
} else {
    for "_i" from 0 to (count _data - 1) step 2 do {
        _key = _data select _i;
        _value = _data select (_i + 1);

        if (_value isEqualType []) then {
            _value = _value select 0;
        };

        switch (_key) do {
            case "funds": { companyFunds = _value; publicVariable "companyFunds" };
            case "rating": { companyRating = _value; publicVariable "companyRating" };
            case "operations": { companyShareholders = _value; publicVariable "companyShareholders" };
        };
    };

    value_serverDone = true;
    publicVariable "value_serverDone";
};