#include "..\script_component.hpp"

/*
 * Function: forge_server_db_fnc_saveToStore
 * Author: J. Schmidt
 * 
 * Description:
 * Saves data to a store in the specified namespace
 *
 * Arguments:
 * 0: _name - Store name <STRING>
 * 1: _data - Data to save <HASHMAP, ARRAY, ANY>
 * 2: _key - Key to save under <STRING>
 * 3: _namespace - Namespace to use (Optional, default: missionNamespace) <NAMESPACE>
 *
 * Return Value:
 * Success <BOOL>
 */

params [
    ["_name", "", [""]],
    ["_data", nil, [createHashMap, [], "", 0, true]],
    ["_key", "", [""]],
    ["_namespace", missionNamespace, [missionNamespace]]
];

if (_name isEqualTo "" || _key isEqualTo "") exitWith {
    ERROR_MSG_2("Invalid store name or key: %1, %2", _name, _key);
    false
};

private _stores = _namespace getVariable [QGVAR(stores), createHashMap];
private _store = _stores getOrDefault [_name, createHashMap];

_store set [_key, _data];
_stores set [_name, _store];
_namespace setVariable [QGVAR(stores), _stores];

switch (_namespace) do {
    case (missionNamespace): { saveMissionProfileNamespace; };
    case (profileNamespace): { saveProfileNamespace; };
};

true